调用 API 并将数据存储到 SQL Server 表中

Question

我正在尝试使用从 Stackoverflow 获得的解决方案来调用 api 并以表格格式解析数据。但是，由于其结构方式，我在解析数据时发现了一个问题。

Declare @Object as Int;
DECLARE @hr  int
Declare @json as table(Json_Table nvarchar(max))

Exec @hr=sp_OACreate 'MSXML2.ServerXMLHTTP.6.0', @Object OUT;`enter code here`
IF @hr <> 0 EXEC sp_OAGetErrorInfo @Object
Exec @hr=sp_OAMethod @Object, 'open', NULL, 'get',
                 'https://accaho.nanorep.co/api/report/v1/get.json?account=accaho&apikey=xxxxxxxxxxxxxxf&days=1&fields=source.time,source.kb_name,source.domain,content.query,content.resultFound,content.articleID,content.articleTitle,content.articleLabels,content.articleContext.Applications,translation.autoTranslated,translation.customersLanguage,translation.originalMessage,channel.rechanneled,channel.channelType,feedback.feedbackType,feedback.feedbackReason,feedback.feedbackText,count.resolved,count.interactions,count.feedback,count.feedbackPositive,count.feedbackNegative&kb=English', --Your Web Service Url (invoked)
                 'false'
IF @hr <> 0 EXEC sp_OAGetErrorInfo @Object
Exec @hr=sp_OAMethod @Object, 'send'
IF @hr <> 0 EXEC sp_OAGetErrorInfo @Object
Exec @hr=sp_OAMethod @Object, 'responseText', @json OUTPUT
IF @hr <> 0 EXEC sp_OAGetErrorInfo @Object

INSERT into @json (Json_Table) exec sp_OAGetProperty @Object, 'responseText'
-- select the JSON string
select * from @json
SELECT * FROM OPENJSON((select * from @json), N'$.rows')

我有点卡在这里......我如何将这些数据解析为表格结构。请帮忙

Answer 1

如果要解析并从 $.rows JSON 数组中获取值，则需要使用额外的 OPENJSON() 调用，因为输入 JSON 的 $.rows 部分是 JSON 数组的 JSON 数组。正确的语法取决于 JSON 结构，您可以使用 default or explict schema 解析输入 JSON：

使用默认模式解析输入 JSON 的 $.rows 部分的语句：

-- .....

SELECT j1.[value], j2.[key], j2.[value] 
FROM @json d
CROSS APPLY OPENJSON(d.Json_Table, N'$.rows') j1
CROSS APPLY OPENJSON(j1.[value]) j2

带有列定义的语句（列名和数据类型可以不同）：

SELECT j1.[value], j2.* 
FROM @json d
CROSS APPLY OPENJSON(d.Json_Table, N'$.rows') j1
CROSS APPLY OPENJSON(j1.[value]) WITH (
    Column1 varchar(100) '$[0]',
    Column2 varchar(100) '$[1]',
    ...
    Column21 varchar(100) '$[20]'
) j2

如果要从输入 JSON 的 $.fields 部分获取列定义，则需要动态语句。

DECLARE @json nvarchar(max) = N'{
    "fields":["source.time","source.kb_name"],
    "rows":[
        ["63725381805336","English","gph.accenture.com"],
        ["63725381805336","English","gph.accenture.com"],
        ["63725381797070","English","gph.accenture.com"],
        ["63725381797070","English","gph.accenture.com"],
        ["63725381755149","English","gph.accenture.com"]
    ]
}'

DECLARE @stm nvarchar(max)
SELECT @stm = STRING_AGG(CONCAT(QUOTENAME([value]), N' varchar(max) ''$[', [key], N']'''), ', ')
FROM OPENJSON(@json, '$.fields')
SELECT @stm = CONCAT(
    N'SELECT * ',
    N'FROM OPENJSON(@json, N''$.rows'') WITH (', @stm, N')'
)

PRINT @stm
EXEC sp_executesql @stm, N'@json nvarchar(max)', @json