如何将 api 请求从测试类发送到 Salesforce 的主类？答案

【问题标题】：How to send api request from test class to Main class in salesforce?如何将 api 请求从测试类发送到 Salesforce 的主类？
【发布时间】：2020-11-06 09:15:00
【问题描述】：

类：

@RestResource(urlMapping='/api/fetch_status/*')
global class RestDemo{

    @HttpGet
    global static Account getResult(){
        
        Account account;
        String accountId = '';
        RestRequest restReq = RestContext.request;
        RestResponse restRes = RestContext.response;
        
        // reading url
        try{
                //accountId = restReq.params.get('accountId');
                accountId = restReq.requestURI.substring(restReq.requestURI.lastIndexOf('/') + 1);        
                
                account = [SELECT Id, Name FROM Account WHERE Id = :accountId Limit 1];
                
                if(account != null){                                       //checked whether any record is returned or not
                        restRes.responseBody = Blob.valueOf(JSON.serialize(account));
                        restRes.statusCode = 200;
                        
                  }else{    
                       /* String account_not_found= '{"message":"Not Found"}';
                          restRes.responseBody = Blob.valueOf(account_not_found);  */ 
                          restRes.statusCode = 404; 
                    }                 
            }
        catch(Exception ex){
            restRes.responseBody = Blob.valueOf(ex.getMessage());
            restRes.statusCode = 500;
            }   
     return account;
    }
}

测试类：

private class RestDemoTest {

    @testSetup
    static void dataSetup() {
        Account acc = new Account(Name = 'Testing5');
        insert acc;
    }
    

    static testMethod void testGet() {
    //case 1 when the id is valid
        Account acc = [ SELECT Id FROM Account LIMIT 1 ];
        RestRequest req = new RestRequest(); 
        RestResponse res = new RestResponse();             
        req.requestURI = '/services/apexrest/api/fetch_status/' + acc.Id;
        req.httpMethod = 'GET';
        RestContext.request = req;
        RestContext.response= res;
        Account acct1 = RestDemo.getResult();
        system.assertEquals(acct1.Name, 'Testing5');
        
     // case 2 when the id is not present 
        String str_id = '0012x000004UjZX';
        Id id = Id.valueOf(str_id);
        req.requestURI = '/services/apexrest/api/fetch_status/' + id;
        req.httpMethod = 'GET';
        RestContext.request = req;
        RestContext.response= res;
        Account acct2 = RestDemo.getResult();
        system.assertEquals(acct2, null); 
        
    }
}

我想测试不存在具有随机 id 的帐户的测试用例 2。但是在测试测试类时（在测试用例 2 中）它给出了异常。

在此我使用了现有的 id 并对其进行了一些更改。因此，当测试用例 2 运行时，它应该通过主类的 else 语句，但它会抛出异常（catch 语句，在 salesforce 开发人员控制台中对其进行了测试）。

【问题讨论】：

标签： api salesforce integration-testing apex

【解决方案1】：

account = [SELECT Id, Name FROM Account WHERE Id = :accountId Limit 1];

您编写它的方式account 永远不会为空。它只会抛出“List has no rows for assignment to SObject”。

改成这个

List<Account> accs = [SELECT Id, Name FROM Account WHERE Id = :accountId Limit 1];
if(!accs.isEmpty()){
   // return 200;
} else {
   // return 400;
}

如果您以这种方式查询，它将始终以列表的形式出现。它可以是空列表，但它将是一个列表（不为空）。仅当您 100% 确定它会返回某些内容时，才将查询结果分配给单个帐户/联系人/...。或者捕获异常

【讨论】：