使用 Delphi Tokyo 10.2 使用 GetObjectProp 获取 TextSettings.Font.Style 属性

Question

我在使用Delphi的GetObjectProp函数获取表单组件的属性，我获取了几个组件的所有属性，但是获取不到TextSettings.Font.Style(Bold, Italic, ...)的属性例如像 TLabel 这样的组件。我需要知道组件文本是粗体还是斜体。我正在尝试获取这些属性的过程如下：

procedure Tfrm1.aoClicarComponente(Sender: TObject);
var
  TextSettings: TTextSettings;
  Fonte: TFont;
  Estilo: TFontStyle;
  Componente_cc: TControl; 
begin
Componente_cc := TControl(Label1);
if IsPublishedProp(Componente_cc, 'TextSettings') then
    begin
      TextSettings := GetObjectProp(Componente_cc, 'TextSettings') as TTextSettings;
        if Assigned(TextSettings) then
           Fonte := GetObjectProp(TextSettings, 'Font') as TFont;
        if Assigned(Fonte) then
           Estilo := GetObjectProp(Fonte, 'Style') as TFontStyle; // <-- error in this line 
        if Assigned(Estilo) then
           Edit1.text := GetPropValue(Estilo, 'fsBold', true);
    end
end; 

我上面标记的那一行显示的错误是。

[dcc64 Error] uPrincipal.pas(1350): E2015 运算符不适用于此操作数类型

我做错了什么？

Answer 1

GetObjectProp(Fonte, 'Style') 将不起作用，因为Style 不是一个基于对象的属性，它是一个基于Set 的属性。而GetPropValue(Estilo, 'fsBold', true) 完全是错误的（并不是说你无论如何都会调用它），因为fsBold 不是属性，它是TFontStyle 枚举的成员。要检索Style 属性值，您必须使用GetOrdProp(Fonte, 'Style')、GetSetProp(Fonte, 'Style') 或GetPropValue(Fonte, 'Style')（分别作为integer、string 或variant）。

话虽如此，一旦您检索到TextSettings 对象，您根本不需要使用RTTI 来访问它的Font.Style 属性，直接访问该属性即可。

试试这个：

procedure Tfrm1.aoClicarComponente(Sender: TObject);
var
  Componente_cc: TControl;
  TextSettings: TTextSettings;
begin
  Componente_cc := ...;
  if IsPublishedProp(Componente_cc, 'TextSettings') then
  begin
    TextSettings := GetObjectProp(Componente_cc, 'TextSettings') as TTextSettings;
    Edit1.Text := BoolToStr(TFontStyle.fsBold in TextSettings.Font.Style, true);
  end;
end; 

更好（和首选）的解决方案是根本不使用 RTTI。具有TextSettings 属性的 FMX 类也针对这种情况实现了ITextSettings 接口，例如：

procedure Tfrm1.aoClicarComponente(Sender: TObject);
var
  Componente_cc: TControl;
  Settings: ITextSettings;
begin
  Componente_cc := ...;
  if Supports(Componente_cc, ITextSettings, Settings) then
  begin
    Edit1.Text := BoolToStr(TFontStyle.fsBold in Settings.TextSettings.Font.Style, true);
  end;
end; 

阅读 Embarcadero 的文档了解更多详情：

Setting Text Parameters in FireMonkey