更改 Delphi 数组范围

Question

我想知道是否有一种方法可以更改我的学校项目的数组范围。这是代码示例（我没有测试过，但我确信它会起作用）：

procedure TfrmWelkom.LeesRekeningeIn(arrInLees : array [1..100,1..2] of string);
var
  iKol,iRy : Integer;
begin
  with dmAlleInlig do
  begin
    tblrekeninge.First;
    while not tblrekeninge.eof do
    begin
      for iKol := 1 to tblrekeninge.Eof do
        for iRy := 1 to 2 do
        begin
          arrInLees[iKol] := tblrekeninge['GebruikersNaam'];
          arrInLees[iRy] := tblrekeninge['Wagwoord'];
          tblrekeninge.Next;
        end;
    end;
  end;
end;

如您所见，我的数组范围是1..100 和1..2。我希望根据数据库中的信息量来更改 100。

希望你能理解。

如果您有更好的方法从 Access 数据库中读取信息，请分享....

我是 StackOverflow 的新手，如有错误请见谅。

Answer 1

你的代码有几个错误：

• 您的数组参数使用了无法编译的非法声明：

  [DCC 错误] E2029 'OF' 预期但发现 '['

• iKol := 1 to tblrekeninge.Eof do 不起作用，您可能打算改用iKol := 1 to 100 do。

• arrInLees[iKol] := ... 应改为 arrInLees[iKol][iRy] := ...。但实际上，您的整个内部 iRy 循环应该被完全删除，它没有正确填充数组。

试试这样的：

type
  TRekeningeArray = array [1..100, 1..2] of string;

function TfrmWelkom.LeesRekeningeIn(var arrInLees : TRekeningeArray): Integer;
var
  iKol : Integer;
begin
  with dmAlleInlig do
  begin
    tblrekeninge.First;
    iKol := 1;
    while (not tblrekeninge.Eof) and (iKol <= 100) do
    begin
      arrInLees[iKol][1] := tblrekeninge['GebruikersNaam'];
      arrInLees[iKol][2] := tblrekeninge['Wagwoord'];
      Inc(iKol);
      tblrekeninge.Next;
    end;
  end;
  Result := iKol - 1; // the actual number of records in the array
end;

然后您可以调整以使用动态数组而不是固定数组：

type
  TRekeninge = record
    GebruikersNaam : string;
    Wagwoord : string;
  end;
  TRekeningeArray = array of TRekeninge;

function TfrmWelkom.LeesRekeningeIn(var arrInLees : TRekeningeArray): Integer;
var
  iKol, iLengte : Integer;
begin
  with dmAlleInlig do
  begin
    tblrekeninge.First;
    iLengte := tblrekeninge.RecordCount;
    SelLength(arrInLees, iLengte);
    iKol := 0;
    while (not tblrekeninge.Eof) and (iKol < iLengte) do
    begin
      arrInLees[iKol].GebruikersNaam := tblrekeninge['GebruikersNaam'];
      arrInLees[iKol].Wagwoord := tblrekeninge['Wagwoord'];
      Inc(iKol);
      tblrekeninge.Next;
    end;
  end;
  Result := iKol;
end;