我什么时候需要释放应用程序创建的数据模块？

Question

我的代码如下：

begin
  Application.Initialize;
  Application.Title := 'Controle Bancário';
  Application.CreateForm(T_DMEstagio, _DMEstagio);
  Application.CreateForm(T_frmLogin, _frmLogin);
  if (_frmLogin.ShowModal = 1) then
    begin
      FreeAndNil(_frmLogin);
      Application.CreateForm(T_frmPrincipal, _frmPrincipal);
      Application.Run;
    end;
    _DMEstagio.Free;

end.

如果我没有像在代码中那样显式释放 DM，我会收到访问冲突异常，但在另一个应用程序中，代码是这样的：

begin
    Application.Initialize;
    Application.Title := ' > Sistema de Gestão Comercial <';
    if HPrevInst = 0 then
    begin
      Application.CreateForm(TFrmPrincipal, FrmPrincipal);
      Application.CreateForm(TIBDM, IBDM);
      Application.Run;
    end ;
end.

我不必释放 DM，也没有任何异常。这是为什么呢？

Answer 1

回答你的问题

“我什么时候需要释放应用程序创建的数据模块？”

永远不会。

使用Application.CreateForm 方法创建的所有数据模块和/或表单将归Application 所有并自动处理。

---

但看起来，您的问题与自动销毁过程无关。以下代码应该可以解决您的问题，因为某些组件和类需要应用程序完成其完整的初始化/运行周期才能优雅地销毁。 RXHook 可能就是其中之一。

begin
  Application.Initialize;
  Application.Title := 'Controle Bancário';
  Application.ShowMainForm := false;
  Application.CreateForm(T_DMEstagio, _DMEstagio);
  Application.CreateForm(T_frmLogin, _frmLogin);
  if (_frmLogin.ShowModal = 1) then
    begin
      FreeAndNil(_frmLogin);
      Application.ShowMainForm := true;
      Application.CreateForm(T_frmPrincipal, _frmPrincipal);
    end
  else Application.Terminate;
  Application.Run;
end.

那么上面的代码到底发生了什么？

您正在尝试显示登录表单并根据登录结果继续运行您的应用程序或终止它。

请务必注意，您创建的第一个表单将变为Application.MainForm，如果该表单在Application.Run 执行之前被释放，Application.MainForm 将被设置回nil。这将确保下一个创建的表单可以成为主表单。

在您的情况下，这意味着 _frmLogin 将被设置为您的 Application.MainForm。如果登录成功，将被释放，_frmPrincipal 将接管。但是如果登录不成功_frmLogin在执行Application.Run时仍然会是Application.MainForm，并且会再次显示。

这就是Application.ShowMainForm 出现的地方。当它设置为false Application.Run 时将运行而不显示任何表单。在您的情况下，它将阻止 _frmLogin 再次出现。当然，在成功登录后，您要将Application.ShowMainForm 设置回true 以确保应用程序正常启动。

在登录失败的情况下调用Application.Terminate 将确保您的应用程序退出应用程序主消息循环，该循环将从调用Application.Run 开始并正常终止。