当我使用“消息”指令时，为什么我没有在我的控制中收到消息？

Question

创建控件后，我必须使用DeviceWnd:=AllocateHWnd(DeviceWindowProc); 接收WM_DEVICECHANGE 消息。然后……

procedure TFileList.DeviceWindowProc(var Message: TMessage);
begin
  case Message.Msg of
    WM_DEVICECHANGE: begin
      case Message.WParam of
        DBT_DEVICEREMOVECOMPLETE, DBT_DEVICEARRIVAL:
          if PDEV_BROADCAST_HDR(Message.LParam).dbch_devicetype = DBT_DEVTYP_VOLUME then
           OnDeviceChange;
      end;
    end;
  end; 
  Message.Result:=DefWindowProc(DeviceWnd, Message.Msg, Message.WParam, Message.LParam);
end;

这很好用，但是当我这样做时，为什么我没有收到该消息？ ：

TFileList = class(TCustomControl)
private
  procedure DeviceChage(var AMessage:TMessage); message WM_DEVICECHANGE;
end;

procedure TFileList.DeviceWindowProc(var Message: TMessage);
begin
  Message.Result:=DefWindowProc(DeviceWnd, Message.Msg, Message.WParam, Message.LParam);
end;

procedure TFileList.DeviceChage(var AMessage:TMessage);
begin
 case AMessage.WParam of
   DBT_DEVICEREMOVECOMPLETE, DBT_DEVICEARRIVAL:
     if PDEV_BROADCAST_HDR(AMessage.LParam).dbch_devicetype = DBT_DEVTYP_VOLUME then
       OnDeviceChange;
 end;
end;

Answer 1

来自RegisterDeviceNotification的文档：

应用程序使用 BroadcastSystemMessage 函数发送事件通知。任何具有顶级窗口的应用程序都可以通过处理 WM_DEVICECHANGE 消息来接收基本通知。应用可以使用 RegisterDeviceNotification 函数注册接收设备通知。

您使用AllocateHWnd 创建的窗口是顶级窗口。因此它接收广播消息。

您的自定义控件不是顶级窗口。如果您希望它接收消息，则必须调用 RegisterDeviceNotification 传递其窗口句柄。如果您这样做，请务必通过在CreateWnd 中注册并在DestroyWnd 中取消注册来处理 VCL 窗口重新创建。

一般来说，AllocateHwnd 是收听通知的首选方式。那是因为它不受 VCL 窗口重新创建的影响，因此不会错过通知。当一个 VCL 窗口被重新创建时，就有一个发送通知的机会窗口，但您的应用程序没有准备好接收的窗口。

这肯定会成为您的问题，因此您应该使用AllocateHwnd。您可以安排您使用AllocateHwnd 创建的窗口归您的自定义控件所有，然后您可以将通知路由到该控件的代码。

Answer 2

WM_DEVICECHANGE 被广播到顶层窗口。您的自定义控件的窗口不是顶级窗口，它是控件的Parent 窗口的子窗口。这就是为什么没有调用您的 message 处理程序的原因 - 消息永远不会到达您的控件的 WndProc()，因此可以将其分派到 message 处理程序。

对于大多数设备通知，您可以使用RegisterDeviceNotification() 将WM_DEVICECHANGE 消息发送到特定的HWND。但是，在您的示例中，volume 更改消息不能像这样注册：

如果 dbch_devicetype 为 DBT_DEVTYP_VOLUME，则函数失败。

因此，要让您的自定义控件接收WM_DEVICECHANGE 消息，它必须分配自己的顶级窗口，例如使用AllocateHwnd() 函数：

type
  // TCustomControl is meant to be used for developing **visual**
  // controls. If your custom control is not visual, you should
  // derive from `TComponent` instead...
  TFileList = class(TCustomControl)
  private
    DeviceWnd: HWND;
    procedure DeviceWindowProc(var Message: TMessage);
  public
    constructor Create(Owner: TComponent); override;
    destructor Destroy; override;
  end;

constructor TFileList.Create(Owner: TComponent);
begin
  inherited Create(Owner);
  if not (csDesigning in ComponentState) then
    DeviceWnd := AllocateHwnd(DeviceWindowProc);
end;

destructor TFileList.Destroy;
begin
  if DeviceWnd <> 0 then
    DeallocateHwnd(DeviceWnd);
  inherited Destroy;
end;

procedure TFileList.DeviceWindowProc(var Message: TMessage);
begin
  if Message.Msg = WM_DEVICECHANGE then
  begin
    case Message.WParam of
      DBT_DEVICEREMOVECOMPLETE, DBT_DEVICEARRIVAL:
        if PDEV_BROADCAST_HDR(Message.LParam).dbch_devicetype = DBT_DEVTYP_VOLUME then
          OnDeviceChange;
    end;
  end;
  Message.Result := DefWindowProc(DeviceWnd, Message.Msg, Message.WParam, Message.LParam);
end;