模态按钮在表单上不起作用

Question

我正在显示一个使用 TActionManager 的表单，如下所示：

procedure TForm2.actAddImagineExecute(Sender: TObject);
begin
  addImagineForm.Show;
end;

表单如下所示：

• 它包含以下内容：3 个TButton、1 个TOpenDialog 和1 个TImage
• 按钮 Salveaza（保存）是 Button3 并且将 ModalResult 设置为 mrOk
• 按钮 Incarca Imagine（加载图像）是 Button1
• 按钮取消为Button2，勾选了Cancel属性并将ModalResult设置为mrAbort

问题：

• 当我点击表单上的Cancel按钮时，它并没有关闭，基本上什么都不做。
• 当我单击表单上的 Salveaza 按钮时，它什么也不做。

Incarca Imagine 按钮的代码如下：

procedure TaddImagineForm.Button1Click(Sender: TObject);
var
  selectedFile: string;
  dlg: TOpenDialog;
begin
  selectedFile := '';
  dlg := TOpenDialog.Create(nil);
  try
    dlg.InitialDir := 'C:\';
    dlg.Filter := 'All files (*.*)|*.*';
    if dlg.Execute(Handle) then
      selectedFile := dlg.FileName;
      Image1.Picture.LoadFromFile(selectedFile);
  finally
    dlg.Free;
  end;
end;

名为Salveaza（Button3）的按钮的代码是：

procedure TaddImagineForm.Button3Click(Sender: TObject);
var
  Field: TBlobField;
  Stream: TStream;
begin
  if dbmodule.comenziQuery.Active and (Image1.Picture.Graphic <> nil) then
  begin
    dbmodule.comenziQuery.Insert;
    Field := TBlobField(dbmodule.comenziQuery.FieldByName('pscreen')); // ensure it ís a blob
    Stream := dbmodule.comenziQuery.CreateBlobStream(Field, bmWrite);
    try
      Image1.Picture.Graphic.SaveToStream(Stream);
    finally
      Stream.Free;
      dbmodule.comenziQuery.Post;
    end;
  end;
end;

• 我正在使用的TSQLQuery（名为comenziQuery）与我正在使用的其他东西（如DataSource、DataSet、@987654344）一起位于Data module @ 等等..) 数据模块被命名为 dbmodule
• 数据库中应保存 .bmp 图像的列名为 pscreen，并设置为 mediumblob 类型。

我尝试过的事情：

• 我尝试添加close; 和modalresult:=mrok;，但它似乎没有执行图像的代码，只是使保存 按钮工作并关闭表单但没有图像添加到数据库字段
• 搜索了这方面的教程，找到了一堆，但它们不是我需要的，或者我显然不明白如何克服这个问题并让它发挥作用

Answer 1

你的问题是行动

procedure TForm2.actAddImagineExecute(Sender: TObject);
begin
  addImagineForm.Show;
end;

应该是

procedure TForm2.actAddImagineExecute(Sender: TObject);
begin
  addImagineForm.ShowModal;
end;

让模态按钮有任何意义。

编辑

另外一个问题是线条

        if dlg.Execute(Handle) then
          selectedFile := dlg.FileName;
          Image1.Picture.LoadFromFile(selectedFile);

您的缩进表明 Image1 只有在 dlg 成功执行时才会尝试加载。不是这种情况。它总是会尝试加载。你的代码应该是

if dlg.Execute(Handle) then
begin
selectedFile := dlg.FileName;
Image1.Picture.LoadFromFile(selectedFile);
end;

编辑2

根据您的评论/要求

procedure TaddImagineForm.Button1Click(Sender: TObject);
begin
    if OpenDialog1.Execute then
    begin
      Image1.Picture.LoadFromFile(OpenDialog1.FileName);
    end;
end;