移动（）从字符串的动态数组中插入/删除项目

Question

使用 System.Move() 从字符串数组中插入/删除项目并不像从其他简单数据类型数组中插入/删除项目那么容易。问题是......字符串在Delphi中被引用计数。对引用计数数据类型使用 Move() 需要更深入地了解内部编译器行为。

这里有人可以解释我实现该目标所需的步骤，或者使用一些 sn-p 代码更好，或者指导我在互联网上找到一个好的参考吗？

哦，请不要告诉我使用“懒惰但慢的方式”，即for循环，我知道。

Answer 1

我之前已经演示过如何从动态数组中删除项目：

• Delphi Q&A: How do I delete an element from an array?

在那篇文章中，我从以下代码开始：

type
  TXArray = array of X;

procedure DeleteX(var A: TXArray; const Index: Cardinal);
var
  ALength: Cardinal;
  i: Cardinal;
begin
  ALength := Length(A);
  Assert(ALength > 0);
  Assert(Index < ALength);
  for i := Index + 1 to ALength - 1 do
    A[i - 1] := A[i];
  SetLength(A, ALength - 1);
end;

您不会出错该代码。使用您想要的X 的任何值；在您的情况下，将其替换为 string。如果您想变得更高级并使用Move，那么也可以这样做。

procedure DeleteX(var A: TXArray; const Index: Cardinal);
var
  ALength: Cardinal;
  TailElements: Cardinal;
begin
  ALength := Length(A);
  Assert(ALength > 0);
  Assert(Index < ALength);
  Finalize(A[Index]);
  TailElements := ALength - Index;
  if TailElements > 0 then
    Move(A[Index + 1], A[Index], SizeOf(X) * TailElements);
  Initialize(A[ALength - 1]);
  SetLength(A, ALength - 1);
end;

由于X 是string，Finalize 调用相当于将空字符串分配给该数组元素。不过，我在这段代码中使用了Finalize，因为它适用于所有数组元素类型，甚至包括记录、接口、字符串和其他数组的类型。

对于插入，您只需将事物向相反的方向移动：

procedure InsertX(var A: TXArray; const Index: Cardinal; const Value: X);
var
  ALength: Cardinal;
  TailElements: Cardinal;
begin
  ALength := Length(A);
  Assert(Index <= ALength);
  SetLength(A, ALength + 1);
  Finalize(A[ALength]);
  TailElements := ALength - Index;
  if TailElements > 0 then begin
    Move(A[Index], A[Index + 1], SizeOf(X) * TailElements);
  Initialize(A[Index]);
  A[Index] := Value;
end;

当您要执行超出语言范围的操作时使用Finalize，例如使用非类型安全的Move 过程覆盖编译器管理类型的变量。重新输入语言的定义部分时使用Initialize。 （该语言定义了当数组使用SetLength 增大或缩小时会发生什么，但它没有定义如何在不使用字符串赋值语句的情况下复制或删除字符串。）

Answer 2

您没有说明保持数组元素的顺序是否对您很重要。 如果订单不相关，您可以像这样非常非常快：

procedure RemoveRecord(Index: integer);  
begin
 FRecords[Index]:= FRecords[High(FRecords)];  { Copy the last element over the 'deleted' element }
 SetLength(FRecords, Length(FRecords)-1);     { Cut the last element }
end;

{ I haven't tested the code to see it compiles, but you got the idea anyway... }

对列表进行排序
如果您有一个巨大的列表需要用户修改，您可以使用与上述类似的方法（打破列表顺序）。当用户完成编辑（多次删除后）时，您会向它显示一个名为“排序列表”的按钮。现在他可以进行冗长的（排序）操作了。
当然，我在上面假设您的列表可以按某个参数排序。

自动排序列表
另一种方法是使分拣过程自动化。当用户从列表中删除内容时，启动一个计时器。如果用户继续删除项目，请继续重置计时器。当计时器成功触发事件时，进行排序，停止计时器。

Answer 3

要插入一个字符串，只需在数组（即指针数组）的末尾添加一个字符串（惰性方式），然后使用Move改变这个数组元素的顺序（的指针）。

Answer 4

如果我想在字符串列表的中间插入一个字符串，我会使用 TStringList.Insert。 （它使用 System.Move 快速完成。）

您使用数组而不是 TStringList 的任何特殊原因？

Answer 5

在弄乱它之前调用 UniqueString()。

http://docwiki.embarcadero.com/VCL/en/System.UniqueString

那么你有一个带有单个引用的字符串。

删除和插入也是如此，我怀疑你会更快。

Answer 6

只是想为将来来到这里的任何人添加这个。

修改 Rob 的代码，我想出了这种使用较新的 TArray<T> 类型构造的方法。

type
  TArrayExt = class(TArray)
    class procedure Delete<T>(var A: TArray<T>; const Index: Cardinal; Count: Cardinal = 1);
  end;

implementation

class procedure TArrayExt.Delete<T>(var A: TArray<T>; const Index: Cardinal;
    Count: Cardinal = 1);
var
  ALength: Cardinal;
  i: Cardinal;
begin
  ALength := Length(A);
  Assert(ALength > 0);
  Assert(Count > 0);
  Assert(Count <= ALength - Index);
  Assert(Index < ALength);

  for i := Index + Count to ALength - 1 do
    A[i - Count] := A[i];

  SetLength(A, ALength - Count);
end;

可以为插入做类似的事情。

（不希望将其标记为答案，只是希望提供一个示例，该示例太长而无法放入 Rob 出色答案的 cmets 中。）

（已修复以解决 Rob 的以下 cmets。）

Answer 7

Move() 适用于引用计数类型（如字符串或接口），实际上在 Delphi 的数组和列表中内部使用。但是，现在，在一般情况下，由于托管记录功能，Move() 不再有效。

Answer 8

如果您使用 System.Move 将项目放入字符串数组中，您应该知道在 Move 之前（现在已被覆盖）的字符串的引用计数为 -1 用于常量字符串，或者> 0 用于变量字符串。不应更改常量字符串，但应相应处理变量字符串：您应该手动降低它们的引用计数（在它们被覆盖之前！）。为此，您应该尝试以下操作：

Dec(PStrRec(IntPtr(SomeString)-12).refCnt);

但是如果引用计数达到零，您还应该确定相关的内存 - 如果您让它工作，Delphi 本身会做得更好，它是字符串的编译器魔法。哦，还有：如果您要复制的字符串与您写入的字符串来自同一个数组，那么所需的管理将变得非常麻烦，非常快！

因此，如果可以通过某种方式避免所有这些手动内务处理，我建议让 Delphi 自己处理。