任务栏上显示多个实例的 SDI 应用程序

Question

我使用 Delphi Berlin VCL 模板创建了一个 SDI 应用程序。我可以通过编程 File|New 来创建额外的实例，如下所示：

procedure TSDIAppForm.FileNew1Execute(Sender: TObject);
var
   LNewDoc: TSDIAppForm;
begin
   LNewDoc := TSDIAppForm.Create(Application);
   LNewDoc.Show;
end;

只有所有者表单显示在任务栏上。此外，关闭所有者表单会关闭所有实例。如何取消链接其他实例，以便它们独立运行并单独显示在任务栏上？

Answer 1

关闭分配为Application.MainForm 的TForm 会退出应用程序，这是设计使然。

如果您希望MainForm 像任何其他 SDI 窗口一样工作，并且在其他 SDI 窗口仍然打开的情况下独立关闭而不退出应用程序，则必须创建一个单独的 TForm 以充当真正的 @987654326 @ 然后对用户隐藏（在调用 Application.Run() 之前在启动时将 Application.ShowMainForm 设置为 false），然后您可以根据需要创建 TSDIAppForm 对象。当最后一个TSDIAppForm对象关闭后，您可以关闭MainForm，或者直接调用Application.Terminate()退出应用程序。

要为每个TSDIAppForm 赋予其自己的任务栏按钮，您需要重写虚拟CreateParams() 方法：

How can I get taskbar buttons for forms that aren't the main form?

试试这个：

begin
  Application.Initialize;
  Application.MainFormOnTaskbar := True;
  Application.CreateForm(TMyRealMainForm, MyRealMainForm);
  Application.CreateForm(TSDIAppForm, SDIAppForm);
  SDIAppForm.Visible := True;
  Application.ShowMainForm := False;
  Application.Run;
end.

procedure TSDIAppForm.CreateParams(var Params: TCreateParams);
begin
  inherited;
  Params.ExStyle := Params.ExStyle or WS_EX_APPWINDOW;
  Params.WndParent := 0;
end;

procedure TSDIAppForm.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caFree;
end;

procedure TSDIAppForm.FormDestroy(Sender: TObject);
begin
  if Screen.FormCount = 2 then // only this Form and the MainForm
    Application.Terminate;
end;

procedure TSDIAppForm.FileNew1Execute(Sender: TObject);
var
  LNewDoc: TSDIAppForm;
begin
  LNewDoc := TSDIAppForm.Create(Application);
  LNewDoc.Show;
end;