使用 Indy 和 smtp 发送邮件

Question

我正在尝试使用此代码发送邮件：

With IdMessage1 Do Begin
  Recipients.EMailAddresses := 'XXXXX@gmail.com';
  From.Address              := 'XXXXX@gmail.com';
  From.Name                 := edit_from.Text;
  CCList.EMailAddresses     := '';
  BccList.EMailAddresses    := '';
  Priority                  := mpNormal;
  Subject                   := edit_subject.Text;
  Body.Add(memo_body.Lines.Text);
End;

With IdSMTP1 Do Begin
  Host      := 'smtp.gmail.com';
  Username  := 'XXXXX@gmail.com';
  Password  := '*****';
  IOHandler := TIdSSLIOHandlerSocketOpenSSL.Create(Self);
  Port      := 465;
  UseTLS    := utUseImplicitTLS;

  Try
    Connect;
  Except
  End;

  If Not Connected Then Begin
    Showmessage('Error');
    Exit;
  End;

  Try
    Send(IdMessage1);
  Finally
    Disconnect;
  End;
End;

它在我的计算机上运行良好，但是当我在其他机器上测试它时，将引发“错误”（在最后一个 Try 块之前的 If 块中出错）... 问题出在哪里？

Answer 1

这不是使用 Indy 进行错误处理的正确方法。它应该更像这样：

With IdSMTP1 Do Begin
  IOHandler := TIdSSLIOHandlerSocketOpenSSL.Create(Self);
  UseTLS    := utUseImplicitTLS;
  Host      := 'smtp.gmail.com';
  Username  := 'XXXXX@gmail.com';
  Password  := '*****';
  Port      := 465;

  Try
    Connect;
    Try
      Send(IdMessage1);
    Finally
      Disconnect;
    End;
  Except
    Showmessage('Error');
    Exit;
  End;
End;

Send() 和 Disconnect() 可以像 Connect() 一样容易失败。如果您希望Connect() 位于其自己的try/except 块中，那么至少不要使用Connected 来验证Connect() 是否成功：

Try
  Connect;
Except
  Showmessage('Error connecting');
  Exit;
End;

Try
  Try
    Send(IdMessage1);
  Finally
    Disconnect;
  End;
Except
  Showmessage('Error sending');
  Exit;
End;

话虽如此，异常会告诉您实际失败的原因，因此请不要忽略它。如果您显示其内容，您会更好地了解失败的原因，例如：

Except
  on E: Exception do
  Begin
    ShowMessage(Format('Error!'#10'[%s] %s', [E.ClassName, e.Message]));
    Exit;
  End;
End;

最可能的罪魁祸首是您没有在您的应用中部署 OpenSSL DLL。您可以从OpenSSL's website 或Indy's Fulgan mirror 下载它们。