获取 Singleton 类 Instance Multi Thread

Question

要获得具有单例模式的类的实例，我想使用以下函数：

这是草图

interface

uses SyncObjs;

type
  TMCriticalSection = class(TCriticalSection)
  private
    Dummy : array [0..95] of Byte;
  end;

var
  InstanceNumber : Integer;
  AObject: TObject;
  CriticalSection: TMCriticalSection;

function getInstance: TObject;

implementation

uses Windows;

function getInstance: TObject;
begin
   //I Want somehow use InterlockedCompareExchange instead of CriticalSession, for example

   if InterlockedCompareExchange(InstanceNumber, 1, 0) > 0 then
   begin
     Result := AObject;
   end
   else
   begin
      CriticalSection.Enter;
      try
        AObject := TObject.Create;
      finally
        CriticalSection.Leave;
      end;
      InterlockedIncrement(InstanceNumber);
      Result := AObject
   end;
end;

initialization
  CriticalSection := TMCriticalSection.Create;
  InstanceNumber := 0;

finalization;
  CriticalSection.Free;

end.

三个问题：

1- 这种设计是线程安全的吗？尤其是带有 InterlockedExchange 的部分。
2- 如何使用 InterlockedCompareExchange？有可能做我正在尝试的事情吗？
3- 这种设计是否比包含关键部分范围内的所有代码更好？

备注： 我的对象是线程安全的，只有我需要序列化的构造！
这不是内部代码，只是重要的部分，我的意思是 getInstance 函数。

编辑

我需要使用某种单例对象。
如果 InstanceNumber 的值为零，有什么方法可以使用 InterlockedCompareExchange 进行比较？
和
1 - 仅当为 0 时才创建对象，否则返回实例。
2 - 当值为 0 时：进入临界区。创建对象。离开临界区。
3 - 这样做会更好，而不是涉及关键部分范围内的所有代码？

Answer 1

有一种称为"Lock-free initialization" 的技术可以满足您的需求：

interface

function getInstance: TObject;

implementation

var
   AObject: TObject;

function getInstance: TObject;
var
   newObject: TObject;
begin
   if (AObject = nil) then
   begin
      //The object doesn't exist yet. Create one.
      newObject := TObject.Create;

      //It's possible another thread also created one.
      //Only one of us will be able to set the AObject singleton variable
      if InterlockedCompareExchangePointer(AObject, newObject, nil) <> nil then
      begin
         //The other beat us. Destroy our newly created object and use theirs.
         newObject.Free;
      end;
   end;

   Result := AObject;
end;

InterlockedCompareExchangePointer 的使用在操作周围建立了一个完整的内存屏障。使用 release 语义 （以确保对象的构造在执行比较交换之前完成）可能能够摆脱InterlockedCompareExchangeRelease。问题在于：

• 我不够聪明，无法知道单独使用 Release 语义是否真的会起作用（只是导致一个比我说的更聪明的人，并不意味着我知道他在说什么）李>
• 您正在构建一个对象，内存屏障性能问题是您最不担心的（这是线程安全）

注意：任何发布到公共领域的代码。无需署名。

Answer 2

您的设计不起作用，即使不了解 InterlockedCompareExchange 的作用，也可以看出这一点。事实上，不管InterlockedCompareExchange是什么意思，你的代码都坏了。

要看到这一点，请考虑两个线程同时到达getInstance 中的if 语句。让我们考虑他们采取哪些分支的三个选项：

1. 他们都选择了第二个分支。然后您创建两个实例，您的代码不再实现单例。
2. 他们都选择了第一个分支。那么你永远不会创建实例。
3. 一个选择第一个，另一个选择第二个。但是由于第一个分支中没有锁，因此采用该路由的线程可以在其他线程写入之前读取AObject。

如果我必须实现你的getInstance 函数，我个人会使用double-checked locking。