AnonymousThread 的结果 - 怎么样？

Question

我尝试做一个函数：

function MyFunction(parameter:string) : string;
begin
      TThread.CreateAnonymousThread(procedure ()
      var temp : string;
      begin
           temp := paramet;
           //some works on temp variable
           result := temp; <-- error here because it is a procedure
      end).Start;
end;

如何让MyFunction在线程结束后返回临时变量？

我也试过这样：

function MyFunction(parameter:string) : string;
vat temp : string;
begin
      TThread.CreateAnonymousThread(procedure ()
      begin
           temp := paramet;
            //some works on temp variable
      end).Start;
result := temp;
end;

以这种方式编译但返回一个空字符串。函数返回结果，不等待线程结束。

或者也许我做错了，因为我没有找到任何示例如何做到这一点？

Answer 1

您不能使用新并行编程库中的 TTask.IFuture 吗？ 它以非常简洁和优雅的方式完全满足您的需求：

FutureObject := TTask.Future<Integer>(function: Integer
     begin
        Sleep(3000);   // to simulate "background processing"
        Result := 16;  // result to be returned as "FutureObject.Value"
     end);

MyValue := FutureObject.Value;  // this waits for the value to be available, if it isn't yet

（示例取自这个 embarcadero wiki 页面 http://docwiki.embarcadero.com/RADStudio/Tokyo/en/Using_TTask.IFuture_from_the_Parallel_Programming_Library

Answer 2

您无法从匿名线程中获得结果。 MyFunction 在线程完成之前立即返回。

---

一种解决方案是使用在线程完成其工作后调用的完成处理程序。

procedure MyProc(parameter: string; Completion: TProc<string>);
begin
  TThread.CreateAnonymousThread(
    procedure
    var
      temp: string;
    begin
      // do something with parameter 
      temp := UpperCase(parameter);
      TThread.Synchronize(nil,
        procedure
        begin
          Completion(temp);
        end);
    end).Start;
end;

然后你这样称呼它：

  MyProc('abc',
    procedure(AValue: string)
    begin
      // do whatever you want with AValue
      Label1.Text := AValue;
    end);