string := const : 为什么本地和结果的实现不同？

Question

在 Delphi 函数中，结果经常被实现为 var-parameter（尽管有 QC 票，但不是 out-parameter）。

字符串常量基本上是具有负引用计数器的变量，应该抑制自动内存[de]分配。 http://docwiki.embarcadero.com/RADStudio/XE3/en/Internal_Data_Formats#Long_String_Types

它确实抑制了它：下面的代码没有泄漏。

type
  TDealRecord = record
    id_Type: Integer;
    Price: extended;
    Remark: String;
  end;
const const_loop = 100000000;

function TestVar: TDealRecord;
//procedure TestVar;
var
  Li: Integer;
  LRec: TDealRecord;
begin
  for Li := 1 to const_loop do begin
     FillChar(Lrec,SizeOf(LRec), 0);
     LRec.Remark := 'Test';

//     FillChar(Result,SizeOf(Result), 0);
//     Result.Remark := 'Test';
  end;
end;

但是改变操纵变量 - 它立即开始大量泄漏。

function TestVar: TDealRecord;
//procedure TestVar;
var
  Li: Integer;
  LRec: TDealRecord;
begin
  for Li := 1 to const_loop do begin
//     FillChar(Lrec,SizeOf(LRec), 0);
//     LRec.Remark := 'Test';

     FillChar(Result,SizeOf(Result), 0);
     Result.Remark := 'Test';
  end;
end;

原来string := const是用不同的调用实现的，具体取决于LValue：

1. 结果：AnsiString -> LStrAsg
2. 结果：UnicodeString：-> UStrAsg
3. 本地变量：UnicodeString：-> UStrLAsg
4. 本地变量：AnsiString：-> LStrLAsg

虽然后两者按预期克隆指针，但前两者将字符串复制到新实例，就像我向它们添加 UniqueString 调用一样。

为什么会有这种差异？

Answer 1

在 Delphi 中，常量字符串在分配给另一个 global 变量时总是被复制，而不是复制给 local 变量，以避免在某些临界情况下访问冲突。

使用来源，卢克！

从System.pas查看这段代码提取：

{ 99.03.11
  This function is used when assigning to global variables.

  Literals are copied to prevent a situation where a dynamically
  allocated DLL or package assigns a literal to a variable and then
  is unloaded -- thereby causing the string memory (in the code
  segment of the DLL) to be removed -- and therefore leaving the
  global variable pointing to invalid memory.
}
procedure _LStrAsg(var dest; const source);
var
  S, D: Pointer;
  P: PStrRec;
  Temp: Longint;
begin
  S := Pointer(source);
  if S <> nil then
  begin
    P := PStrRec(Integer(S) - sizeof(StrRec));
    if P.refCnt < 0 then   // make copy of string literal
    begin
      Temp := P.length;
      S := _NewAnsiString(Temp);
      Move(Pointer(source)^, S^, Temp);
      P := PStrRec(Integer(S) - sizeof(StrRec));
    end;
    InterlockedIncrement(P.refCnt);
  end;
....

简而言之，为了避免在卸载 DLL 或包并且确实包含一些发送回主进程的常量值时发生访问冲突，总是会制作本地副本。

你有两个功能：

• LStrAsg 或 UStrAsg 在字符串有机会成为常量时由编译器生成 - 这是上面的代码；
• LStrLAsg 或 UStrLAsg（添加的L 代表“本地”）由编译器在源字符串为本地时生成，因此没有常量：在这种情况下，P.refCnt < 0 不会被检查，所以会比上面的代码快。

Answer 2

在与 David Heffernan 讨论之后，我开始认为 Delphi 编译器只是不知道它分配给变量的值是什么。有一种“类型擦除”的地方。它无法从本地堆栈变量和本地字符串表达式中分辨出全局常量。它无法判断函数退出发生后源是否存在。虽然我们知道这是字符串文字或全局常量或任何与函数执行无关的生命周期 - 编译器只是丢失了该信息。相反，它起到防御作用，总是克隆价值——只是为了它不再存在的机会。我不确定，但这看起来很合理。尽管这种粗略的不分青红皂白的代码生成规则的后果是 Delphi 中的另一个 gotcha :-(