用 indy delphi7 发送表情符号答案

【问题标题】：Send emoji with indy delphi7用 indy delphi7 发送表情符号
【发布时间】：2023-03-14 05:49:01
【问题描述】：

我想在 delphi 7 上使用 indy 9.00.10 发送表情符号。我使用 tnt VCL Controls 。我找到了这个 url http://apps.timwhitlock.info/emoji/tables/unicode 用于 unicode 和 bytes 代码。如何将此代码转换为使用 indy 发送的 delphi 常量。

我使用这个 delphi 代码向电报机器人发送消息：

procedure TBotThread.SendMessage(ChatID:String; Text : WideString;
parse_mode:string;disable_notification:boolean);
Var
  Stream: TStringStream;
  Params: TIdMultipartFormDataStream;
  //Text : WideString;
  msg : WideString;
  Src : string;
  LHandler: TIdSSLIOHandlerSocket;
begin
  try
    try
      if FShowBotLink then
        Text := Text + LineBreak + FBotUser;
      msg := '/sendmessage';
      Stream := TStringStream.Create('');
      Params := TIdMultipartFormDataStream.Create;
      Params.AddFormField('chat_id',ChatID);
      if parse_mode <> '' then
        Params.AddFormField('parse_mode',parse_mode);
      if disable_notification then
        Params.AddFormField('disable_notification','true')
      else
        Params.AddFormField('disable_notification','false');
      Params.AddFormField('disable_web_page_preview','true');
      Params.AddFormField('text',UTF8Encode(Text));
      LHandler := TIdSSLIOHandlerSocket.Create(nil);
      FidHttpSend.ReadTimeout := 30000;
      FidHttpSend.IOHandler:=LHandler;
      LHandler.SSLOptions.Method := sslvTLSv1;
      LHandler.SSLOptions.Mode := sslmUnassigned;
      FidHttpSend.HandleRedirects := true;
      FidHttpSend.Post(BaseUrl + API + msg, Params, Stream);
    finally
      Params.Free;
      Stream.Free;
    ENd;
 except
   on E: EIdHTTPProtocolException do
   begin
      if E.ReplyErrorCode = 403 then
      begin
       WriteToLog('Bot was blocked by the user');
      end;
   end;
 end;  
end;

表情符号的字节样本：

AERIAL_TRAMWAY = '\xf0\x9f\x9a\xa1';
AIRPLANE = '\xe2\x9c\x88';
ALARM_CLOCK = '\xe2\x8f\xb0';
ALIEN_MONSTER = '\xf0\x9f\x91\xbe';

抱歉英语不好！！！

【问题讨论】：

Indy 9 不支持 Unicode。您应该升级到 Indy 10。如果这不是一个选项，我将不得不深入研究 Indy 9 的代码，以便为您提供其他选项。无论哪种方式，您实际发布到哪个 URL？发布 Unicode 输入有什么要求？
感谢雷米的评论。我更改此行以发送电话表情符号。 Params.AddFormField('text',UTF8Encode(Text + LineBreak + #$0000260E ));这对我有用，但此代码不起作用：#$1F601 表示“笑脸笑脸”表情符号。我发布到电报机器人 API：api.telegram.org/bot。表情符号是unicode吗？ .抱歉英语不好。
如何将emoji代码示例U+1F601转换并在delphi中使用？

标签： delphi unicode delphi-7 emoji indy-9

【解决方案1】：

Telegram Bot API 支持多种输入形式：

我们支持GET 和POST HTTP 方法。我们支持四种方式在 Bot API 请求中传递参数：

网址查询字符串

application/x-www-form-urlencoded

application/json（上传文件除外）

multipart/form-data（用于上传文件）

您使用的是最后一个选项。

Indy 9 不支持 Delphi 2009+ 或 Unicode。所有string 的使用都假定为AnsiString，在Delphi 7 中就是这种情况。您添加到TIdMultipartFormDataStream 或TStrings 的任何AnsiString，甚至是UTF-8 编码的@，都将被传输按原样由TIdHTTP。但是，没有选项可以向服务器指定字符串数据实际上使用 UTF-8 作为字符集。但是，根据文档：

所有查询都必须使用 UTF-8。

所以不指定显式字符集可能不是问题。

如果您对multipart/form-data 仍有问题，请考虑改用application/x-www-form-urlencoded（使用TIdHTTP.Post(TStrings)）或application/json（使用TIdHTTP.Post(TStream)）：

procedure TBotThread.SendMessage(ChatID: String; Text: WideString; parse_mode: string; disable_notification: boolean);
var
  Params: TStringList;
  LHandler: TIdSSLIOHandlerSocket;
begin
  if FShowBotLink then
    Text := Text + LineBreak + FBotUser;

  Params := TStringList.Create;
  try
    Params.Add('chat_id=' + UTF8Encode(ChatID));
    if parse_mode <> '' then
      Params.Add('parse_mode=' + UTF8Encode(parse_mode));
    if disable_notification then
      Params.Add('disable_notification=true')
    else
      Params.Add('disable_notification=false');
    Params.Add('disable_web_page_preview=true');
    Params.Add('text=' + UTF8Encode(Text));

    LHandler := TIdSSLIOHandlerSocket.Create(nil);
    try
      LHandler.SSLOptions.Method := sslvTLSv1;
      LHandler.SSLOptions.Mode := sslmClient;

      FidHttpSend.HandleRedirects := true;
      FidHttpSend.ReadTimeout := 30000;
      FidHttpSend.IOHandler := LHandler;
      try
        try
          FidHttpSend.Post(BaseUrl + API + '/sendmessage', Params, TStream(nil));
        except
          on E: EIdHTTPProtocolException do
          begin
            if E.ReplyErrorCode = 403 then
            begin
              WriteToLog('Bot was blocked by the user');
            end;
          end;
        end;  
      finally
        FidHttpSend.IOHandler := nil;
      end;
    finally
      LHandler.Free;
    end;
  finally
    Params.Free;
  end;
end;

procedure TBotThread.SendMessage(ChatID: String; Text: WideString; parse_mode: string; disable_notification: boolean);
var
  Params: TStringStream;
  LHandler: TIdSSLIOHandlerSocket;

  function JsonEncode(const wStr: WideString): string;
  var
    I: Integer;
    Ch: WideChar;
  begin
    // JSON uses UTF-16 text, so no need to encode to UTF-8...
    Result := '';
    for I := 1 to Length(wStr) do
    begin
      Ch := wStr[i];
      case Ch of
        #8: Result := Result + '\b';
        #9: Result := Result + '\t';
        #10: Result := Result + '\n';
        #12: Result := Result + '\f';
        #13: Result := Result + '\r';
        '"': Result := Result + '\"';
        '\': Result := Result + '\\';
        '/': Result := Result + '\/';
      else
        if (Ord(Ch) >= 32) and (Ord(Ch) <= 126) then
          Result := Result + AnsiChar(Ord(wStr[i]))
        else
          Result := Result + '\u' + IntToHex(Ord(wStr[i]), 4);
      end;
    end;
  end;

begin
  if FShowBotLink then
    Text := Text + LineBreak + FBotUser;

  Params := TStringStream.Create('');
  try
    Params.WriteString('{');
    Params.WriteString('chat_id: "' + JsonEncode(ChatID) + '",');
    if parse_mode <> '' then
      Params.WriteString('parse_mode: "' + JsonEncode(parse_mode) + '",')
    if disable_notification then
      Params.WriteString('disable_notification: True,')
    else
      Params.WriteString('disable_notification: False,');
    Params.WriteString('disable_web_page_preview: True,');
    Params.WriteString('text: "' + JsonEncode(Text) + '"');
    Params.WriteString('}');
    Params.Position := 0;

    LHandler := TIdSSLIOHandlerSocket.Create(nil);
    try
      LHandler.SSLOptions.Method := sslvTLSv1;
      LHandler.SSLOptions.Mode := sslmClient;

      FidHttpSend.HandleRedirects := true;
      FidHttpSend.ReadTimeout := 30000;
      FidHttpSend.IOHandler := LHandler;
      try
        try
          FidHttpSend.Request.ContentType := 'application/json';
          FidHttpSend.Post(BaseUrl + API + '/sendmessage', Params, TStream(nil));
        except
          on E: EIdHTTPProtocolException do
          begin
            if E.ReplyErrorCode = 403 then
            begin
              WriteToLog('Bot was blocked by the user');
            end;
          end;
        end;  
      finally
        FidHttpSend.IOHandler := nil;
      end;
    finally
      LHandler.Free;
    end;
  finally
    Params.Free;
  end;
end;

话虽如此，您的函数的Text 参数是WideString，它使用UTF-16，因此您应该能够发送任何Unicode 文本，包括表情符号。如果您尝试在代码中生成文本，只需确保 UTF-16 对任何非 ASCII 字符进行正确编码。例如，代码点 U+1F601 GRINNING FACE WITH SMILING EYES 在 UTF-16 中是宽字符 $D83D $DE01：

var
  Text: WideString;

Text := 'hi ' + #$D83D#$DE01; // 'hi ?'
SendMessage('@channel', Text, 'Markup', False);

或者，您可以在文本消息中使用 HTML，这样您就可以使用数字 HTML 实体对非 ASCII 字符进行编码。根据文档：

支持所有数字 HTML 实体。

代码点 U+1F601 是 HTML 中的数字实体 $#128513;：

var
  Text: WideString;

Text := 'hi $#128513;'; // 'hi ?'
SendMessage('@channel', Text, 'HTML', False);

【讨论】：