在 Delphi 中，Math.Round() 和 MidpointRounding.AwayFromZero 的等价物是什么？

Question

如何在 Delphi 中使用类似于 Math.Round 和 MidpointRounding.AwayFromZero 的 c#？

相当于：

double d = 2.125;
Console.WriteLine(Math.Round(d, 2, MidpointRounding.AwayFromZero));

输出：2.13

在德尔福？

Answer 1

我相信 Delphi RTL 的 SimpleRoundTo 函数基本上可以做到这一点，至少如果 FPU 舍入模式是“正确的”。请仔细阅读其文档和实现，然后确定它是否足以满足您的目的。

但请注意，设置像这样的单个舍入操作的舍入模式是使用全局更改来解决局部问题。这可能会导致问题（多线程、库等）。

奖金喋喋不休：如果问题是关于“常规”舍入（到整数），我想我已经尝试过类似的方法

function RoundMidpAway(const X: Real): Integer;
begin
  Result := Trunc(X);
  if Abs(Frac(X)) >= 0.5 then
    Inc(Result, Sign(X));
end;

改为。

当然，即使对于 n 小数的一般情况，也可以编写类似的函数。 （但要注意正确处理边缘情况、溢出、浮点问题等。）

更新：我相信以下方法可以解决问题（而且速度很快）：

function RoundMidpAway(const X: Real): Integer; overload;
begin
  Result := Trunc(X);
  if Abs(Frac(X)) >= 0.5 then
    Inc(Result, Sign(X));
end;

function RoundMidpAway(const X: Real; ADigit: integer): Real; overload;
const
  PowersOfTen: array[-10..10] of Real =
    (
      0.0000000001,
      0.000000001,
      0.00000001,
      0.0000001,
      0.000001,
      0.00001,
      0.0001,
      0.001,
      0.01,
      0.1,
      1,
      10,
      100,
      1000,
      10000,
      100000,
      1000000,
      10000000,
      100000000,
      1000000000,
      10000000000
    );
var
  MagnifiedValue: Real;
begin
  if not InRange(ADigit, Low(PowersOfTen), High(PowersOfTen)) then
    raise EInvalidArgument.Create('Invalid digit index.');
  MagnifiedValue := X * PowersOfTen[-ADigit];
  Result := RoundMidpAway(MagnifiedValue) * PowersOfTen[ADigit];
end;

当然，如果您要在生产代码中使用此功能，您还需要添加至少 50 个单元测试用例来测试其正确性（每天运行）。

更新：我相信以下版本更稳定：

function RoundMidpAway(const X: Real; ADigit: integer): Real; overload;
const
  FuzzFactor = 1000;
  DoubleResolution = 1E-15 * FuzzFactor;
  PowersOfTen: array[-10..10] of Real =
    (
      0.0000000001,
      0.000000001,
      0.00000001,
      0.0000001,
      0.000001,
      0.00001,
      0.0001,
      0.001,
      0.01,
      0.1,
      1,
      10,
      100,
      1000,
      10000,
      100000,
      1000000,
      10000000,
      100000000,
      1000000000,
      10000000000
    );
var
  MagnifiedValue: Real;
  TruncatedValue: Real;
begin

  if not InRange(ADigit, Low(PowersOfTen), High(PowersOfTen)) then
    raise EInvalidArgument.Create('Invalid digit index.');
  MagnifiedValue := X * PowersOfTen[-ADigit];

  TruncatedValue := Int(MagnifiedValue);
  if CompareValue(Abs(Frac(MagnifiedValue)), 0.5, DoubleResolution * PowersOfTen[-ADigit]) >= EqualsValue  then
    TruncatedValue := TruncatedValue + Sign(MagnifiedValue);

  Result := TruncatedValue * PowersOfTen[ADigit];

end;

但我还没有完全测试它。 （目前它通过了900+ unit test cases，但我认为测试套件还不够充分。）

Answer 2

您正在寻找的是 SimpleRoundTo 函数与 SetRoundMode 的组合。正如文件所说：

SimpleRoundTo 返回具有指定 10 次幂的最接近的值。如果AValue 恰好位于具有指定十次幂的两个最接近值的中间（高于和低于），则此函数返回：

• 如果AValue 是正数，则向正无穷大的值。

• 如果AValue 为负且 FPU 舍入模式未设置为 rmUp，则值朝负无穷大

请注意，函数的第二个参数是TRoundToRange，它指的是指数（10 的幂），而不是 .NET 的Math.Round 方法中的小数位数。因此，要舍入到小数点后 2 位，请使用 -2 作为舍入范围。

uses Math, RTTI;

var
  LRoundingMode: TRoundingMode;
begin
  for LRoundingMode := Low(TRoundingMode) to High(TRoundingMode) do
  begin
    SetRoundMode(LRoundingMode);
    Writeln(TRttiEnumerationType.GetName(LRoundingMode));
    Writeln(SimpleRoundTo(2.125, -2).ToString);
    Writeln(SimpleRoundTo(-2.125, -2).ToString);
  end;
end;

rm最近的

2,13

-2,13

rmDown

2,13

-2,13

rmUp

2,13

-2,12

rm截断

2,13

-2,13