为什么这个 PAnsiChar 在转换为 AnsiString 时会被截断？

Question

请考虑以下程序：

program SO41175184;

{$APPTYPE CONSOLE}

uses
  SysUtils;

function Int9999: PAnsiChar;
begin
  Result := PAnsiChar(AnsiString(IntToStr(9999)));
end;

function Int99999: PAnsiChar;
begin
  Result := PAnsiChar(AnsiString(IntToStr(99999)));
end;

function Int999999: PAnsiChar;
begin
  Result := PAnsiChar(AnsiString(IntToStr(999999)));
end;

function Str9999: PAnsiChar;
begin
  Result := PAnsiChar(AnsiString('9999'));
end;

function Str99999: PAnsiChar;
begin
  Result := PAnsiChar(AnsiString('99999'));
end;

function Str999999: PAnsiChar;
begin
  Result := PAnsiChar(AnsiString('999999'));
end;

begin
  WriteLn(Int9999); // '9999'
  WriteLn(Int99999); // '99999'
  WriteLn(Int999999); // '999999'

  WriteLn(string(AnsiString(Str9999))); // '9999'
  WriteLn(string(AnsiString(Str99999))); // '99999'
  WriteLn(string(AnsiString(Str999999))); // '999999'

  WriteLn(string(AnsiString(PAnsiChar(AnsiString(IntToStr(9999)))))); // '9999'
  WriteLn(string(AnsiString(PAnsiChar(AnsiString(IntToStr(99999)))))); // '99999'
  WriteLn(string(AnsiString(PAnsiChar(AnsiString(IntToStr(999999)))))); // '999999'

  WriteLn(string(AnsiString(Int9999))); // '9999'
  WriteLn(string(AnsiString(Int99999))); // '9999' <----- ?!
  WriteLn(string(AnsiString(Int999999))); // '999999'

  ReadLn;
end.

只有在其中一种情况下，字符串才会丢失单个字符，在 Delphi 2010 和 Delphi XE3 中都是如此。使用 FPC，相同的程序可以正常工作。切换到PChar 也会让问题消失。

我想这与内存管理有关，但我没有足够的线索去寻找进行有意义的调查。谁能澄清一下？

Answer 1

对动态创建的字符串进行引用计数，并在没有引用时释放。

Result := PAnsiChar(AnsiString(IntToStr(99999)));

导致创建一个临时的AnsiString，其地址通过转换为PAnsiChar，然后释放临时字符串^†。结果指针指向现在无人认领的内存，几乎可以出于任何原因覆盖该内存，包括在分配更多字符串期间。

默认情况下，Delphi 和 FPC 都不会在释放期间清除内存，因此如果尚未重新使用内存，那么在读取曾经存在的内容时可能会很幸运。或者，如您所见，您可能不会。

当像这样返回PAnsiChar时，你需要在调用者和被调用者之间就内存管理达成一致。您需要确保不要提前释放内存，并且您需要确保调用者知道之后如何释放内存。

_{^† Remy Lebeau 指出，这种释放发生在过程或函数返回时。如果在分配给Result 之后还有另一个语句，则该字符串仍然可用。这通常是正确的，但也有临时字符串在返回之前被释放的情况，例如当您在循环中创建临时字符串时。我不建议在创建它们的语句结束后使用临时对象，即使在它有效的情况下也是如此，因为它很难验证代码是否正确。对于这些情况，只需使用显式变量。}