如何使用 TControl 附加任何类型的对象？

Question

我想添加一个带有 TTreeViewItem 的 TList 和一个带有另一个自定义类 (TRoom) 的对象。在delphi 2007中，有一个指针类型的“数据”字段已被替换为此处的TValue，我不知道如何使用。我已经在互联网上搜索了一些说它暂时无法处理自定义类型。

除了制作一个 hack 类之外，有人可以设计一种方法来实现这一点吗？

例如，下面的表单代码应该可以正常运行：-

unit Unit1;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Rtti, System.Classes,
  System.Variants, FMX.Types, FMX.Controls, FMX.Forms, FMX.Dialogs,
  FMX.TreeView, FMX.Layouts, FMX.Edit;

type
  TRoom = class

    ID : WORD;
    Name : String;

  end;

  TForm1 = class(TForm)
    TreeView1: TTreeView;
    TreeViewItem1: TTreeViewItem;
    Button1: TButton;
    Edit1: TEdit;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.fmx}

procedure TForm1.Button1Click(Sender: TObject);
var
  List : TList;
begin

  // Get The List From TreeViewItem1
  // pani's Solution  - List := TList ( TreeViewItem1.TagObject );

  Edit1.Text := TRoom ( List.First ).Name;

end;

procedure TForm1.FormCreate(Sender: TObject);
var
  Room : TRoom;
  List : TList;

begin

  List := TList.Create;
  Room := TRoom.Create;
  Room.ID := 5;
  Room.Name := IntToStr ( 5 );
  List.Add ( Room );

  // Add The List To TreeViewItem1    
  // pani's Solution  - TreeViewItem1.TagObject := List;

end;

end.

Answer 1

如果你想将一个对象“附加”到 TControl，TControl 的父类 TFmxObject 引入了存储任何对象值的 .TagObject 属性。

除了使用此属性之外，您还可以使用 .Tag 属性将类型转换为 NativeInt 和您想要的类类型，例如：TreeViewItem1.Tag := NativeInt(List);和列表：= TList(TreeViewItem1.Tag);

Answer 2

在“小“g””通用方式中，FMX 控件的Data 属性应该获取或设置控件的核心值。在TImage 的情况下，这将是显示的位图，在TEdit 的情况下将是文本等等。因此，它的目的与 VCL 树视图项的 Data 属性完全不同，后者是从对象中挂起任意数据。

正如 pani 正确回答的那样，如果您想挂起对 FMX 树视图项的任意对象引用，那么您可以使用 TagObject。 也就是说，尽管对 FMX 对正确 OOP 行为的影响（参见 here）感到恼火，但如果您正在动态创建树视图项目，那么更好的方法可能是派生自定义 TTreeViewItem 后代：

uses System.Generics.Collections;

type
  TRoomTreeViewItem = class(TTreeViewItem)
    RoomList: TList<TRoom>; //better use a generic than non-generic list as mentioned above
  end;

或者，如果房间列表的生命周期与其关联的树视图项的生命周期相同，您实际上可以将列表封装在项目中：

type
  TRoomTreeViewItem = class(TTreeViewItem)
  strict private
    FRoomList: TObjectList<TRoom>;
    function GetRoom(Index: Integer): TRoom;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
    function GetEnumerator: TEnumerator<TRoom>;
    function AddRoom: TRoom;
    property Rooms[Index: Integer] read GetRoom;
  end;

constructor TRoomTreeViewItem.Create(AOwner: TComponent);
begin
  inherited;
  FRoomList := TObjectList<TRoom>.Create;
end;

destructor TRoomTreeViewItem.Destroy;
begin
  FRoomList.Free;
  inherited;
end;

function TRoomTreeViewItem.GetEnumerator: TEnumerator<TRoom>;
begin
  Result := FRoomList.GetEnumerator;
end;

function TRoomTreeViewItem.GetRoom(Index: Integer): TRoom;
begin
  Result := FRoomList[Index];
end;

function TRoomTreeViewItem.AddRoom: TRoom;
begin
  Result := TRoom.Create;
  FRoomList.Add(Result);
end;

有些人可能会认为第二个变体是非 UI 与 UI 代码的可怕混合——尽管 YMMV，但我个人并不反对它（事实上，这就是我建议它的原因）。