Delphi Tstringlist，将字符串作为带引号的逗号分隔字符串？

Question

我有一个包含在数据库表中使用的键列表的 Tstringlist。 我想要一种简单的方法来生成一个包含所有键的字符串，每个键用逗号分隔并用单引号括起来。 这样它就可以在 SQL 'IN' 语句中使用 例如WHERE FieldX IN ('One','Two','Three').

我尝试过使用quotechar，但在阅读 commatext 时它会被忽略。 比如下面的代码

procedure junk;
var
  SL : Tstringlist;
  s : string;
begin
 SL := Tstringlist.Create;
 SL.Delimiter :=','; //comma delimiter
 SL.QuoteChar := ''''; //single quote around strings
 SL.Add('One');
 SL.Add('Two');
 SL.Add('Three');
 try
   s :=  SL.commatext;
   showmessage(s);
 finally
   SL.Free;
 end; //finally
end; //junk

显示消息 One,Two,Three - 不带任何引号。

我知道我可以做到这一点，就像在

procedure junk;
var
  SL : Tstringlist;
  s : string;
  i : integer;
begin
 SL := Tstringlist.Create;
 SL.Delimiter :=','; //comma delimiter
 SL.Add('One');
 SL.Add('Two');
 SL.Add('Three');
 try
 s := '';
 for I := 0 to SL.Count - 1 do
    begin
    s := s +  ',' + '''' + SL[i] + '''';
    end;
 delete(s,1,1);
 showmessage(s);
 finally
   SL.Free;
 end;//finally
end;

但是有没有更简单的方法使用 Tstringlist 本身的属性？

Answer 1

如果您使用的是 D2006 或更高版本，则可以使用 CLASS HELPER：

USES Classes,StrUtils;

TYPE
  TStringListHelper = CLASS HELPER FOR TStrings
                        FUNCTION ToSQL : STRING;
                      END;

FUNCTION TStringListHelper.ToSQL : STRING;
  VAR
    S : STRING;

  FUNCTION QuotedStr(CONST S : STRING) : STRING;
    BEGIN
      Result:=''''+ReplaceStr(S,'''','''''')+''''
    END;

  BEGIN
    Result:='';
    FOR S IN Self DO BEGIN
      IF Result='' THEN Result:='(' ELSE Result:=Result+',';
      Result:=Result+QuotedStr(S)
    END;
    IF Result<>'' THEN Result:=Result+')'
  END;

这段代码：

SL:=TStringList.Create;
SL.Add('One');
SL.Add('Two');
SL.Add('Number Three');
SL.Add('It''s number 4');
WRITELN('SELECT * FROM TABLE WHERE FIELD IN '+SL.ToSQL);

然后会输出：

SELECT * FROM TABLE WHERE FIELD IN ('One','Two','Number Three','It''s number 4')

Answer 2

使用sl.DelimitedText 而不是sl.CommaText 使其符合您的设置。 CommaText 将暂时将 Delimiter 和 QuoteChar 更改为一些硬编码值。

Answer 3

不能依赖 CommaText（显然还有 DelimitedText）来添加引号，因为它们对单个单词和多单词字符串的处理方式不同。

检索 CommaText 时，列表中包含空格的任何字符串， 逗号或引号将包含在双引号中，并且任何双引号 字符串中的引号将被重复。

单独使用 TStringList 似乎没有任何组合，因此我建议您使用 QuotedStr 添加字符串。 无论字符串是单个单词还是多个单词，以下设置都可以按照您的意愿工作：

 SL := Tstringlist.Create;
 SL.Delimiter :=','; //comma delimiter
 SL.StrictDelimiter := True;
// SL.QuoteChar := ''''; //single quote around strings
// SL.Add('One');
// SL.Add('Two words');
// SL.Add('Three');
 SL.Add(QuotedStr('One'));
 SL.Add(QuotedStr('Two words'));
 SL.Add(QuotedStr('Three'));
 s := SL.CommaText; // or SL.DelimitedText;
 showmessage(s);

输出是：

'一个','两个字','三个'

Answer 4

TStrings.DelimitedText 方法仅在需要时引用字符串：当有链接 O'ne 时，这将打印为 'O''ne' - 即双引号。

您可以实现您想要的设置便利分隔符和QuoteChar 属性为#0 值，然后用引号替换分隔符。

procedure junk;
var
  sl : Tstringlist;
  s: string;
begin
  sl := Tstringlist.Create;
  try
    sl.Delimiter := '|';
    sl.QuoteChar := #0;//no quote
    sl.Add('On''e');
    sl.Add('Two');
    sl.Add('Three');

    //escape the single quotes
    s := StringReplace(sl.DelimitedText, '''', '''''', [rfReplaceAll]);

    //replace the delimiters and quote the text
    s := '''' +  StringReplace(s, sl.Delimiter, ''',''', [rfReplaceAll]) + '''';

    WriteLn(s);

  finally
    sl.Free;
  end;
end;

Answer 5

我已经解决了类似的问题：

  s := ''' + StringReplace(sl.CommaText, ',', ''',''', [rfReplaceAll]) + '''