迁移到 Delphi XE7 后，StrAlloc 无法正常工作

Question

我正在开发一个最近从 Delphi 2007 升级到 XE7 的应用程序。在一种特殊情况下，将 TMemoryStream 转换为 PChar 失败。代码如下：

procedure TCReport.CopyToClipboard;
var
  CTextStream: TMemoryStream;
  PValue: PChar;
begin
    CTextStream := TMemoryStream.Create;
    //Assume that this code is saving a report column to CTextStream
    //Verified that the value in CTextStream is correct
    Self.SaveToTextStream(CTextStream);

    //The value stored in PValue below is corrupt
    PValue := StrAlloc(CTextStream.Size + 1);
    CTextStream.Read(PValue^, CTextStream.Size + 1);
    PValue[CTextStream.Size] := #0;

    { Copy text stream to clipboard }
    Clipboard.Clear;
    Clipboard.SetTextBuf(PValue);

    CTextStream.Free;

    StrDispose(PValue);
end;

为 SaveToTextStream 添加代码：

procedure TCReport.SaveToTextStream(CTextStream: TStream);
var
  CBinaryMemoryStream: TMemoryStream;
  CWriter: TWriter;
begin

  CBinaryMemoryStream := TMemoryStream.Create;
  CWriter := TWriter.Create(CBinaryMemoryStream, 24);

  try
    CWriter.Ancestor := nil;
    CWriter.WriteRootComponent(Self);
    CWriter.Free;

    CBinaryMemoryStream.Position := 0;

    { Convert Binary 'WriteComponent' stream to text}

    ObjectBinaryToText(CBinaryMemoryStream, CTextStream);
    CTextStream.Position := 0;
  finally
    CBinaryMemoryStream.Free;
  end;
end;

我观察到 StrLen(PChar) 的大小也只有 TMemoryStream 的一半。但在 Delphi 2007 中，它与 TMemoryStream 的大小相同。

我知道上面的代码假设 char 的大小为 1 个字节，这可能是个问题。但是我尝试了多种方法，但没有任何效果。

您能否建议一种更好的方法来进行这种转换？

Answer 1

再一次，这是 Delphi 2009 及更高版本使用 Unicode 文本的问题。在 Delphi 2007 及更早版本中：

• Char 是 AnsiChar 的别名。
• PChar 是 PAnsiChar 的别名。
• string 是 AnsiString 的别名。

在 Delphi 2009 及更高版本中：

• Char 是 WideChar 的别名。
• PChar 是 PWideChar 的别名。
• string 是 UnicodeString 的别名。

您的代码是假设PChar 是PAnsiChar。因此你的问题。无论如何，您都需要停止使用StrAlloc。通过在此处手动分配堆内存，您正在为自己感到难过。让编译器完成工作。

你需要在一个字符串变量中获取你的文本，然后简单的做：

Clipboard.AsText := MyStrVariable;

究竟如何最好地获取字符串取决于TCReport 提供的设施。我希望它会直接产生一个字符串，在这种情况下你会写这样的东西：

procedure TCReport.CopyToClipboard;
begin
  Clipboard.AsText := Self.ReportAsText;
end;

我猜你的TCReport 提供什么功能，但我相信你知道。

Answer 2

通过参考上面hvd 和David Heffernan 写的内容，一种可能的方法是将CopyToClipboard 上的CTextStream 更改为TStringStream，如下所示：

procedure TCReport.CopyToClipboard;
var
  CTextStream: TStringStream;
begin
    CTextStream := TStringStream.Create;
    try
      //Assume no error with Self.SaveToTextStream
      Self.SaveToTextStream(CTextStream);

      { Copy text stream to clipboard }
      Clipboard.AsText := CTextStream.DataString;
    finally
      CTextStream.Free;
    end;
end;

但您应该确保SaveToTextStream 函数为CTextStream 提供准确的编码文本数据。