分配具有相互依赖维度的动态数组

Question

这有点复杂；我欢迎任何关于如何提高问题清晰度的 cmets。

好的，假设我有一个数组：

real, allocatable :: A(:,:,:)

我想在使用它之前分配它。第三维度的大小是否可能取决于第二维度的大小？

例如

do i=1,n
allocate(A(3,i,i**2))
end do

显然以上方法行不通。我想最终得到一个具有形状的数组（或一组数组）

(3,1,1), (3,2,4), (3,3,9), ... (3, n, n^2)

其中第三维的大小是第二维大小的平方。

我对依赖维度大小的规则有点复杂，但如果可以平方，我可以做剩下的事情。

这可能吗？如果是这样，我该如何在 Fortran 中实现它？

shape(A) 会返回什么？那会很有趣。

我的另一种选择是分配到所需的最大大小，并注意仅在计算中使用某些元素，即

allocate(A(3,n,n**2))

尽管目前我的记忆力并不强，但我希望有良好的编程习惯。无论如何，这是一个有趣的问题。

谢谢。

编辑：

如果一个维度的大小取决于另一个维度中元素的值呢？

在下面的答案中，两个维度的数组大小取决于 B 的索引。我想要一些类似于

的东西

type myarray
    real :: coord(3)
    integer,allocatable :: lev(:)
    integer, allocatable :: cell(:)
endtype myarray

type(myarray), allocatable :: data

allocate(data(m))
allocate(data%lev(n))

forall (j=1:n) !simple now, for argument's sake
    lev(j)=j
endforall

! I was thinking of using a FORALL loop here, but the errors returned 
! suggested that the compiler (gfortran) didn't expect IF blocks and ALLOCATE 
! statements in a FORALL block
do i=1,m
    do j=1,n
        allocate(data(i)%cell(lev(j)**2))
    enddo
enddo

你明白我的意思吗？但是程序在尝试分配已经分配的变量时失败了，例如当i=1 分配data(1)%cell(1)，然后尝试分配data(1)%cell(2)...呃哦。我想要的是这样的：

每个data(i) 都有一个lev(j) 值数组，j 从 1 到 n 运行，对于每个 lev(j) 值，我们有一个大小为 lev^2 的 cell。请注意，这些cell 对于每个data(i) 和每个lev 都是唯一的，并且该特定cell 的大小取决于相应的lev 值，也可能取决于相应的data(i)。

我必须在派生类型中使用派生类型吗？

Answer 1

我认为你可以简单地通过分配/释放数组来做到这一点

Program test
    Implicit none
    Real, dimension(:,:,:), allocatable :: A
    Integer  :: i,N
    Write(*,*)"Enter N"; Read(*,*)N
    Do i = 1, N
    if(Allocated(A)) then 
    deallocate(A);Allocate(A(i,i,i*i))
    else
    allocate(A(i,i,i*i))
    end if
    Write(*,*)Shape(A)
    End do
end program test

使用 gfortran 编译程序给出：

 Enter N
5
           1           1           1
           2           2           4
           3           3           9
           4           4          16
           5           5          25

Answer 2

是的，您可以使用派生类型来完成此操作：

TYPE array
  REAL,DIMENSION(:,:,:),ALLOCATABLE :: A
ENDTYPE array

INTEGER :: i
INTEGER,PARAMETER :: n=10

TYPE(array),DIMENSION(:),ALLOCATABLE :: B

ALLOCATE(B(n))

DO i=1,n
  ALLOCATE(B(i)%A(3,i,i*i))
  WRITE(*,*)SHAPE(B(i)%A)
ENDDO

END

这种方法允许数组 B 的每个元素成为不同形状的多维数组。

程序的输出如预期：

        3            1            1
        3            2            4
        3            3            9
        3            4           16
        3            5           25
        3            6           36
        3            7           49
        3            8           64
        3            9           81
        3           10          100

编辑：进一步回答 OP 的编辑问题。是的，您似乎需要做这样的事情，使用嵌套派生类型（比较您的代码示例以找出您做错了什么）：

integer,parameter :: m=3,n=5

type cellarray
  integer,dimension(:),allocatable :: c
endtype cellarray

type myarray
  integer,allocatable :: lev(:)
  type(cellarray),dimension(:),allocatable :: cell
endtype myarray

type(myarray),dimension(:),allocatable :: B

allocate(B(m))

! Allocate and assign lev and cell:
do i=1,m
  allocate(B(i)%lev(n))
  allocate(B(i)%cell(n))
  do j=1,n
    B(i)%lev(j)=j
  enddo
enddo

! Based on value of lev, allocate B%cell%c:    
do i=1,m
  do j=1,n
    allocate(B(i)%cell(j)%c(B(i)%lev(j)**2))
  enddo
enddo

! Print out to check that it works:
do j=1,n
  write(*,*)j,B(1)%lev(j),SIZE(B(1)%cell(j)%c)
enddo

end

用 gfortran 4.6.2 试过这个。它产生预期的输出：

       1           1           1
       2           2           4
       3           3           9
       4           4          16
       5           5          25