在结构上使用“new”是否会在堆或堆栈上分配它？

Question

当您使用new 运算符创建类的实例时，内存会在堆上分配。当您使用 new 运算符创建结构的实例时，内存在哪里分配，在堆上还是在堆栈上？

Answer 1

好的，让我们看看我是否可以更清楚地说明这一点。

首先，Ash 是对的：问题不是关于值类型变量 的分配位置。这是一个不同的问题——答案不仅仅是“在堆栈上”。它比这更复杂（C# 2 使它变得更加复杂）。我有一个article on the topic，如果需要，我会对其进行扩展，但我们只处理new 运算符。

其次，所有这些都取决于您所谈论的级别。我正在查看编译器对源代码的处理，就它创建的 IL 而言。 JIT 编译器很可能会在优化大量“逻辑”分配方面做一些聪明的事情。

第三，我忽略了泛型，主要是因为我实际上并不知道答案，部分是因为它会使事情变得过于复杂。

最后，所有这些都只是当前的实现。 C# 规范没有详细说明这一点——它实际上是一个实现细节。有些人认为托管代码开发人员真的不应该关心。我不确定我会走那么远，但值得想象一个实际上所有局部变量都存在于堆上的世界——这仍然符合规范。

---

在值类型上使用new 运算符有两种不同的情况：您可以调用无参数构造函数（例如new Guid()）或有参数构造函数（例如new Guid(someString)）。这些产生显着不同的IL。要了解原因，您需要比较 C# 和 CLI 规范：根据 C#，所有值类型都有一个无参数构造函数。根据 CLI 规范，no 值类型具有无参数构造函数。 （有时会通过反射获取值类型的构造函数 - 你不会找到无参数的构造函数。）

C# 将“用零初始化值”视为构造函数是有意义的，因为它使语言保持一致 - 您可以将 new(...) 视为 总是 调用构造函数。 CLI 有不同的想法是有意义的，因为没有真正的代码可以调用 - 当然也没有特定于类型的代码。

在你初始化它之后你将如何处理它也会有所不同。 IL用于

Guid localVariable = new Guid(someString);

不同于用于以下用途的 IL：

myInstanceOrStaticVariable = new Guid(someString);

此外，如果该值用作中间值，例如方法调用的参数，情况又略有不同。为了显示所有这些差异，这里有一个简短的测试程序。它没有显示静态变量和实例变量之间的区别：stfld 和 stsfld 之间的 IL 会有所不同，但仅此而已。

using System;

public class Test
{
    static Guid field;

    static void Main() {}
    static void MethodTakingGuid(Guid guid) {}


    static void ParameterisedCtorAssignToField()
    {
        field = new Guid("");
    }

    static void ParameterisedCtorAssignToLocal()
    {
        Guid local = new Guid("");
        // Force the value to be used
        local.ToString();
    }

    static void ParameterisedCtorCallMethod()
    {
        MethodTakingGuid(new Guid(""));
    }

    static void ParameterlessCtorAssignToField()
    {
        field = new Guid();
    }

    static void ParameterlessCtorAssignToLocal()
    {
        Guid local = new Guid();
        // Force the value to be used
        local.ToString();
    }

    static void ParameterlessCtorCallMethod()
    {
        MethodTakingGuid(new Guid());
    }
}

这是类的 IL，不包括不相关的位（例如 nops）：

.class public auto ansi beforefieldinit Test extends [mscorlib]System.Object    
{
    // Removed Test's constructor, Main, and MethodTakingGuid.

    .method private hidebysig static void ParameterisedCtorAssignToField() cil managed
    {
        .maxstack 8
        L_0001: ldstr ""
        L_0006: newobj instance void [mscorlib]System.Guid::.ctor(string)
        L_000b: stsfld valuetype [mscorlib]System.Guid Test::field
        L_0010: ret     
    }

    .method private hidebysig static void ParameterisedCtorAssignToLocal() cil managed
    {
        .maxstack 2
        .locals init ([0] valuetype [mscorlib]System.Guid guid)    
        L_0001: ldloca.s guid    
        L_0003: ldstr ""    
        L_0008: call instance void [mscorlib]System.Guid::.ctor(string)    
        // Removed ToString() call
        L_001c: ret
    }

    .method private hidebysig static void ParameterisedCtorCallMethod() cil  managed    
    {   
        .maxstack 8
        L_0001: ldstr ""
        L_0006: newobj instance void [mscorlib]System.Guid::.ctor(string)
        L_000b: call void Test::MethodTakingGuid(valuetype [mscorlib]System.Guid)
        L_0011: ret     
    }

    .method private hidebysig static void ParameterlessCtorAssignToField() cil managed
    {
        .maxstack 8
        L_0001: ldsflda valuetype [mscorlib]System.Guid Test::field
        L_0006: initobj [mscorlib]System.Guid
        L_000c: ret 
    }

    .method private hidebysig static void ParameterlessCtorAssignToLocal() cil managed
    {
        .maxstack 1
        .locals init ([0] valuetype [mscorlib]System.Guid guid)
        L_0001: ldloca.s guid
        L_0003: initobj [mscorlib]System.Guid
        // Removed ToString() call
        L_0017: ret 
    }

    .method private hidebysig static void ParameterlessCtorCallMethod() cil managed
    {
        .maxstack 1
        .locals init ([0] valuetype [mscorlib]System.Guid guid)    
        L_0001: ldloca.s guid
        L_0003: initobj [mscorlib]System.Guid
        L_0009: ldloc.0 
        L_000a: call void Test::MethodTakingGuid(valuetype [mscorlib]System.Guid)
        L_0010: ret 
    }

    .field private static valuetype [mscorlib]System.Guid field
}

如你所见，调用构造函数有很多不同的指令：

• newobj：在堆栈上分配值，调用参数化构造函数。用于中间值，例如用于分配给字段或用作方法参数。
• call instance：使用已分配的存储位置（无论是否在堆栈上）。这在上面的代码中用于分配给局部变量。如果使用多次 new 调用多次为同一个局部变量分配一个值，它只会在旧值的顶部初始化数据 - 它不会每次都分配更多的堆栈空间。
• initobj：使用已分配的存储位置并擦除数据。这用于我们所有的无参数构造函数调用，包括那些分配给局部变量的调用。对于方法调用，有效地引入了一个中间局部变量，其值被initobj 擦除。

我希望这能说明这个话题是多么复杂，同时又能对它有所启发。在一些概念意义上，每次对new 的调用都会在堆栈上分配空间——但正如我们所见，即使在IL 级别，这也不是真正发生的情况。我想强调一个特殊情况。采取这种方法：

void HowManyStackAllocations()
{
    Guid guid = new Guid();
    // [...] Use guid
    guid = new Guid(someBytes);
    // [...] Use guid
    guid = new Guid(someString);
    // [...] Use guid
}

“逻辑上”有 4 个堆栈分配 - 一个用于变量，一个用于三个 new 调用中的每一个 - 但实际上（对于该特定代码）堆栈只分配一次，然后是相同的存储位置被重复使用。

编辑：为了清楚起见，这仅在某些情况下是正确的......特别是，如果 Guid 构造函数抛出异常，guid 的值将不可见，这就是 C# 编译器的原因能够重用相同的堆栈槽。请参阅 Eric Lippert 的 blog post on value type construction 了解更多详细信息以及它不适用的情况。

我在写这个答案的过程中学到了很多 - 如果有任何不清楚的地方，请要求澄清！

Answer 2

根据具体情况，可以在堆栈或堆上分配包含结构字段的内存。如果 struct-type 变量是某个匿名委托或迭代器类未捕获的局部变量或参数，则它将在堆栈上分配。如果变量是某个类的一部分，那么它将在堆上的类中分配。

如果结构是在堆上分配的，那么实际上不需要调用 new 运算符来分配内存。唯一的目的是根据构造函数中的内容设置字段值。如果没有调用构造函数，那么所有字段都将获得它们的默认值（0 或 null）。

对于分配在堆栈上的结构类似，除了 C# 要求所有局部变量在使用之前设置为某个值，因此您必须调用自定义构造函数或默认构造函数（不带参数的构造函数是总是可用于结构）。

Answer 3

简而言之，new 是结构体的误称，调用 new 只是调用构造函数。结构的唯一存储位置是它定义的位置。

如果是成员变量，则直接存储在定义的任何地方，如果是局部变量或参数，则存储在堆栈中。

将其与类进行对比，类在结构完整存储的任何地方都有引用，而引用指向堆上的某个位置。 （内部成员，本地/堆栈上的参数）

稍微了解一下 C++ 可能会有所帮助，其中类/结构之间没有真正的区别。 （语言中有类似的名称，但它们仅指事物的默认可访问性）当您调用 new 时，您将获得指向堆位置的指针，而如果您有非指针引用，则它直接存储在堆栈中或在另一个对象中，C# 中的 ala 结构。

Answer 4

与所有值类型一样，结构体总是位于它们被声明的位置。

有关何时使用结构的更多详细信息，请参阅此问题here。 这个问题here 了解更多关于结构的信息。

编辑：我错误地回答他们总是进入堆栈。这是incorrect。

Answer 5

我可能在这里遗漏了一些东西，但我们为什么要关心分配？

值类型是按值传递的；）因此不能在与定义它们的范围不同的范围内进行变异。为了能够改变值，您必须添加 [ref] 关键字。

引用类型通过引用传递，并且可以改变。

当然，不可变引用类型字符串是最受欢迎的。

数组布局/初始化： 值类型 -> 零内存 [name,zip][name,zip] 引用类型 -> 零内存 -> null [ref][ref]

Answer 6

class 或 struct 声明就像用于在运行时创建实例或对象的蓝图。如果你定义了一个class 或struct 叫Person，Person 就是类型的名字。如果您声明并初始化一个 Person 类型的变量 p，则 p 被称为 Person 的对象或实例。可以创建多个相同 Person 类型的实例，每个实例的 properties 和 fields 可以有不同的值。

class 是一个引用类型。当创建class 的对象时，分配给该对象的变量只保存对该内存的引用。当对象引用分配给新变量时，新变量引用原始对象。通过一个变量所做的更改会反映在另一个变量中，因为它们都引用相同的数据。

struct 是一个值类型。创建struct 时，分配struct 的变量保存结构的实际数据。当struct 分配给一个新变量时，它会被复制。因此，新变量和原始变量包含相同数据的两个单独副本。对一个副本所做的更改不会影响另一个副本。

一般来说，classes 用于建模更复杂的行为，或在创建 class 对象后打算修改的数据。 Structs 最适合主要包含在创建 struct 后不打算修改的数据的小型数据结构。

for more...

Answer 7

几乎所有被认为是值类型的结构都在堆栈上分配，而对象在堆上分配，而对象引用（指针）在堆栈上分配。

Answer 8

结构被分配到堆栈。这是一个有用的解释：

Structs

此外，在 .NET 中实例化的类会在 堆或 .NET 的保留内存空间。而结构产生更多 由于堆栈上的分配，实例化时的效率。 此外，应该注意的是，在结构中传递参数 是按价值来做的。