如何在 Google Sheets 中合并两个数组查询的代码答案

【问题标题】：How to combine the code of two array queries in Google Sheets如何在 Google Sheets 中合并两个数组查询的代码
【发布时间】：2019-08-08 20:53:17
【问题描述】：

我需要合并两个都在 arrayformulas 中的查询，这样我就只有一个查询：

我尝试过使用 Union

第一个密码：

 = ARRAYFORMULA(QUERY({MID(Sheet1!B1:B, 8, 5), Sheet1!A1:AS}, 
 "select count(Col13) 
 where Col13>=0 
 group by Col1 
 label count(Col13)'Winners #'"))

第二个密码：

= ARRAYFORMULA(QUERY({MID(Sheet1!B1:B, 8, 5), Sheet1!A1:AS}, 
"select count(Col13) 
where Col13<=0 
group by Col1 
label count(Col13)'Losers #'"))

【问题讨论】：

欢迎。请您分享一份您的电子表格副本（不包括任何私人或机密数据）。
@Tedinoz: docs.google.com/spreadsheets/d/…
@Tedinoz “分组项目”选项卡包含数据，“表 1”包含我要合并的两个查询，“表 2”包含已排序的日期，但我也想知道如何向该查询添加更多选择，例如“count(Col3)”，但这需要添加更多列。如果你知道如何做到这一点，那就太好了。非常感谢你

标签： regex google-sheets google-sheets-formula array-formulas google-sheets-query

【解决方案1】：

=ARRAYFORMULA(QUERY(REGEXREPLACE(TO_TEXT(QUERY({
 QUERY({MONTH(MID('grouping project'!A2:A, 8, 3)&1)&"♦"&
              MID('grouping project'!A2:A, 8, 5), 'grouping project'!A2:AO}, 
 "select Col1,count(Col3),'Winners #'
  where Col1 is not null 
    and Col3 >= 0 
  group by Col1 
  label count(Col3)'','Winners #'''", 0);
 QUERY({MONTH(MID('grouping project'!A2:A, 8, 3)&1)&"♦"&
              MID('grouping project'!A2:A, 8, 5), 'grouping project'!A2:AO}, 
 "select Col1,count(Col3),'Loosers #'
  where Col3 <= 0 
    and Col1 is not null
  group by Col1 
  label count(Col3)'','Loosers #'''", 0)}, 
 "select Col1,sum(Col2)
  group by Col1
  pivot Col3
  label Col1'Week ending'", 0)), "^.+♦", ), 
 "where Col1 is not null", 0))

【讨论】：

非常感谢。我是 SQL 新手……无论如何你可以描述一下代码吗？
@ajg 基本上，您的两个查询都放在彼此下方，并为每个查询分配了“假”列（赢家或输家）。然后将其作为一个整体再次置于查询下，我们使用假总和，因此我们可以根据假赢/输列对其进行旋转。正则表达式只是为了修复 A 列的年表
一件艺术品——从哪里开始？在MONTH 的公式中，您能解释一下&1 的用途吗？在第二个MID 中，&"♦"& 将MONTH 值与Mid 值连接起来的目的是什么？在第一个SELECT 语句中，在count 语句之后'Winners #' 的意义是什么？我注意到稍后在 SELECT 中添加了一个标签。
为了转换月份名称，例如。一月、二月等到您需要的数字：=MONTH("Jan"&1)，因此是 MONTH 和 &1。然后我们用唯一的符号♦加入它（可以是任何符号♪♫♥♣♠♂♀...）所以A列中的内容看起来像：01♦Jan11，01♦Jan18，01♦Jan25，02♦Feb01，@ 987654339@ 等这样，A 列可以按时间顺序很好地排序，在其排序后，多余的东西会被正则表达式公式 "^.+♦" 删除 - 翻译为“删除从开始到唯一符号的所有内容 ♦ 包括唯一符号本身”
@player0 感谢您的解释。