Google 表格：如果时间在 23:00 至 05:00（或 11:00 PM 至 05:00 AM）范围内，则返回“False”答案

【问题标题】：Google sheets: Returns "False" if the time is in the range from 23:00 to 05:00 (or from 11:00 PM to 05:00 AM)Google 表格：如果时间在 23:00 至 05:00（或 11:00 PM 至 05:00 AM）范围内，则返回“False”
【发布时间】：2021-01-12 12:24:41
【问题描述】：

我的公式应该返回 4 个不同的文本值，具体取决于单元格中的时间值。

一切正常，但是每次我尝试让公式查看从 23:00 到 05:00 的时间，如果在完整的公式中，它总是返回 False 或 #N/A。我尝试了 12 小时格式，但效果相同。

=IFS(
AND(TEXT(C18,"HH:MM")>="05:00",TEXT(C18,"HH:MM")<="10:59"),"SS",
AND(TEXT(C18,"HH:MM")>="11:00",TEXT(C18,"HH:MM")<="16:59"),"AA",
AND(TEXT(C18,"HH:MM")>="17:00",TEXT(C18,"HH:MM")<="22:59"),"MM",
AND(TEXT(C18,"HH:MM")>="23:00",TEXT(C18,"HH:MM")<="04:59"),"LL")

除了最后一行之外，此公式中的所有内容都正确。返回的是 # N/A，而不是 LL。我不明白为什么会这样。

【问题讨论】：

标签： date datetime google-sheets google-sheets-formula ifs

【解决方案1】：

尝试：

=VLOOKUP(C18, {
 0,              "LL"; 
 VALUE("5:00"),  "SS";
 VALUE("11:00"), "AA";
 VALUE("17:00"), "MM";
 VALUE("23:00"), "LL"}, 2, 1)

或：

=VLOOKUP(TIMEVALUE(C18), {
 TIMEVALUE("00:00"), "LL"; 
 TIMEVALUE("05:00"), "SS";
 TIMEVALUE("11:00"), "AA";
 TIMEVALUE("17:00"), "MM";
 TIMEVALUE("23:00"), "LL"}, 2, 1)

【讨论】：

你的第二种方法效果很好！但我不太明白怎么做。不知道这个公式可以这样用。

【解决方案2】：

尝试：

=IFS(
 (TEXT(C18, "HH:MM")>="05:00")*(TEXT(C18, "HH:MM")<="10:59"), "SS",
 (TEXT(C18, "HH:MM")>="11:00")*(TEXT(C18, "HH:MM")<="16:59"), "AA",
 (TEXT(C18, "HH:MM")>="17:00")*(TEXT(C18, "HH:MM")<="22:59"), "MM",
((TEXT(C18, "HH:MM")>="23:00")*(TEXT(C18, "HH:MM")<="23:59"))+
((TEXT(C18, "HH:MM")>="00:00")*(TEXT(C18, "HH:MM")<="04:59")), "LL")

【讨论】：

【解决方案3】：

更新答案：

由于您覆盖了一天中的全部时间范围，如果IFS 的返回值为NA，则表示没有匹配。在这种情况下，返回LL：

=ifna(IFS(
AND(TEXT(C18,"HH:MM")>="05:00",TEXT(C18,"HH:MM")<="10:59"),"SS",
AND(TEXT(C18,"HH:MM")>="11:00",TEXT(C18,"HH:MM")<="16:59"),"AA",
AND(TEXT(C18,"HH:MM")>="17:00",TEXT(C18,"HH:MM")<="22:59"),"MM"),"LL")

【讨论】：

非常感谢！现在我会知道的。