当我指的是未命名的范围时出现运行时错误“1004”答案

【问题标题】：Run-time error '1004' when I'm referring to a range that is not named当我指的是未命名的范围时出现运行时错误“1004”
【发布时间】：2019-09-11 10:53:36
【问题描述】：

我正在尝试在 Excel 工作表中放置一个下拉菜单，其中包含另一个工作表中的选项，以及另一个工作簿中的选项。我使用 VBA 是因为 我想根据另一个下拉菜单自定义这些选项。我设法通过命名源工作表中的范围来做到这一点，但该文件是只读的，因此我无法保存名称以自动执行该过程。所以我尝试只使用引用中的列名（如 $B:$B，我只需要 B 列），但是当我运行宏时，它会因运行时错误 1004 而停止。

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim KeyCells As Range
    Set KeyCells = Range("H6")

    If Not Application.Intersect(KeyCells, Range(Target.Address)) Is Nothing Then
        Call main
    End If
End Sub

Private Sub main()
    reason = Range("H6").Value
    List = ""

    If reason = "Project ID/Task ID" Then
        List = "=PIDTID"
    Else
        List = "=Cost_Center"
    End If

    With Range("I6").Validation
        .Delete
        .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _
            Operator:=xlBetween, Formula1:=List
        .IgnoreBlank = True
        .InCellDropdown = True
        .InputTitle = ""
        .ErrorTitle = ""
        .InputMessage = ""
        .ErrorMessage = ""
        .ShowInput = True
        .ShowError = True
    End With
End Sub

这是我的宏，如您所见，main() 在 H6 更改时被调用，因为那是我的另一个下拉菜单所在的位置。然后，根据该单元格中的值，为 List 分配一个值，该值等于定义的名称，该名称引用另一个工作表中的范围。

例如，如果 PIDTID 名称等于 ='[20190812_WP_and_CostCenters_Responsible.xls]Projects responsibles'!WBSName，则脚本有效。请注意，WBSName 是源工作表中 B 列的名称。

如果我将 PIDTID 设置为='[20190812_WP_and_CostCenters_Responsible.xls]Projects responsibles'!$B:$B，我将在线收到错误

.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _ Operator:=xlBetween, Formula1:=List

Cost_Center 名称的作用相同。

我想提一下，这些测试是在打开源文件的情况下完成的。如果我尝试关闭它，我会得到同样的错误。

有没有办法摆脱错误，或者我可以通过其他方式引用其他工作簿工作表中的单元格而不命名它们？我也想工作而不必打开源文件。谢谢！

【问题讨论】：

根据this 文档，错误本身是非常合乎逻辑的。

标签： excel vba worksheet-function worksheet

【解决方案1】：

“有没有办法摆脱错误，或者我可以通过其他方式引用其他工作簿工作表中的单元格而不命名它们？我也想工作而不必打开源文件. 谢谢！”

让我试一试:)

根据this 文档，您不能使用对另一个工作簿的引用（没有命名范围）。当然不是在封闭的工作簿中。请参阅@Gh3ttoKinG 他的回答:)。

所以这可能会做得更聪明，但要做到这一点不打开我考虑过使用ExecuteExcel4Macro 的工作簿。在@SiddharthRout 的this 回答的帮助下，我们可以开始从关闭的工作簿中提取信息：

Sub Test()

Dim wbPath As String, wbName As String
Dim wsName As String, cellRef As String
Dim Ret As String
Dim lr As Long
Dim arr() As String

wbPath = "C:\Users\....\SO\"
wbName = "SO.xlsx"
wsName = "Sheet1"

'Get the last row from B column, notice we need R1C1 notation for Excel4Macro
lr = ExecuteExcel4Macro("COUNTA('" & wbPath & "[" & wbName & "]" & wsName & "'!C2)")

'Let's use an array to fill our validation list with later on
ReDim arr(1 To lr)
For x = 1 To lr
    arr(x) = ExecuteExcel4Macro("'" & wbPath & "[" & wbName & "]" & wsName & "'!R" & x & "C2")
Next x

'Join the array together to make a string which will be accepted in the validation list
With Range("I6").Validation
    .Delete
    .Add Type:=xlValidateList, Formula1:=Join(arr, ",")
    .IgnoreBlank = True
    .InCellDropdown = True
    .InputTitle = ""
    .ErrorTitle = ""
    .InputMessage = ""
    .ErrorMessage = ""
    .ShowInput = True
    .ShowError = True
End With

End Sub

有些事情我会尝试“平滑”，例如 COUNTA 不是获得 lr 变量的最佳方法，另外可能有一种方法可以将完整范围拉入 arr() 变量中一次。

不过，这可能会激发一些创意；）

编辑

另一种检索字符串数据最后一行的方法是使用MATCH，如下所示：

lr = ExecuteExcel4Macro("MATCH(""zzz"",'" & wbPath & "[" & wbName & "]" & wsName & "'!C2)")

【讨论】：

感谢您，这对我很有帮助，甚至可以进一步帮助我解决一些我不知道如何解决的问题。但是，我遇到了一个起初没有的新问题：COUNTA 返回值 983237，除非我正在读取的文件已打开。你知道为什么会这样吗？
@VladIordache，我提供了另一个选项，它可能对您有用吗？如果这没有帮助，实际上您的列中可能有值。甚至空格或公式输出可能是“”？
谢谢您，先生，现在可以正常使用了。我没有值，因为打开文件时输出是正确的。 COUNTA、COUNTIF、SUMPRODUCT 的行为相同，甚至 ROWS 和 COUNTBLANK 之间的差异也是如此。但是您使用MATCH 的解决方案正是我所需要的，再次感谢您。不过，我还是想知道那个奇怪的数字是怎么回事

【解决方案2】：

正如 JvdV 在 cmets 中所写，这是因为您不能在列表引用另一个工作簿的情况下使用数据验证，至少不能以简单的方式。

您可以通过使用此公式将命名范围添加到可写工作簿来绕过它（假设 Cost_Center 在 C 列中）

=IF(Sheet1!H6="PIDTID",OFFSET('[20190812_WP_and_CostCenters_Responsible.xls]Projects responsibles'!$B:$B,0,0),OFFSET('[20190812_WP_and_CostCenters_Responsible.xls]Projects responsibles'!$C:$C,0,0))

然后在您的数据验证/宏中使用这个命名范围。缺点是必须打开源工作簿才能使下拉菜单起作用

【讨论】：