围绕 Google 表格移动日历事件答案

【问题标题】：Moving Calendar Events around Google Sheets围绕 Google 表格移动日历事件
【发布时间】：2020-08-05 19:15:03
【问题描述】：

我订阅了一系列 Google 日历。在我完成大部分工作的主电子表格中，我有一个启动页面，我希望从每个日历中提取今天和明天的事件。

数据从 Google 日历中提取并放入名为 Under The Hood 的隐藏工作表中。然后，我使用以下查询尝试提取 A) 相关和 B) 今天（或明天，两个不同的查询）发生的查询。

今天的活动

=QUERY('Under The Hood'!M4:O13, "select M, N where M contains 'P/U' or M contains 'D/O' and toDate(O) contains 'toDate(TODAY())'",0)

明天的活动

=QUERY('Under The Hood'!M4:O13, "select M, N where M contains 'P/U' or M contains 'D/O' and O contains date'" & TEXT(TODAY()+1,"yyyy-mm-dd")&"'",0)

这两个查询都为我提供了明天和后天的相同部分事件列表。

【问题讨论】：

分享您的工作表副本
@player0 我不得不复制并删除一些可识别的信息，但这里是电子表格的一个非常截断的版本。 docs.google.com/spreadsheets/d/… 启动页单元格 F4 和 I4 是相关查询所在的位置。

【解决方案1】：

你的公式应该是：

=QUERY('Under The Hood'!M4:O, 
 "select M,N 
  where M matches '.*P/U.*|.*D/O.*' 
    and O contains date '"&TEXT(TODAY()+1, "yyyy-mm-dd")&"'", 0)

【讨论】：

【解决方案2】：

解决方案

你现在的逻辑陈述是这样的：

M contains 'P/U' or (M contains 'D/O' and O contains date'" & TEXT(TODAY()+1,"yyyy-mm-dd")&"')

（插入显式括号）

这意味着只要检查 M 是否包含 'P/U' 就会返回 true。

你应该以一种能够检查的方式来制定你的逻辑陈述：

M = 'P/U' and O = 'date you want' or M = 'D/O' and O = 'date you want'

为此，只需按照文档的建议将 M 列上的逻辑语句包装在括号内：

您可以使用逻辑运算符 and、or 和 not 连接多个条件。括号可用于定义明确的优先级。

=QUERY('Under The Hood'!M4:O13, "select M, N where (M contains 'P/U' or M contains 'D/O') and O contains date '"& TEXT(TODAY(), "yyyy-mm-dd")&"'",0)

【讨论】：