包含日期操作的查询函数 [DATE + X 月数]答案

【问题标题】：Query function to contain date operations [DATE + X number of months]包含日期操作的查询函数 [DATE + X 月数]
【发布时间】：2019-04-02 14:00:45
【问题描述】：

我正在使用一个相对简单的表达式查询一个 Google 电子表格：

=QUERY(Sheet1!A1:J200, "Select A, J", 1)

此查询在 L 和 M 列中生成 Offices 和 Last N date 列表 - 见下图.

我接下来要做的是

在最后 N 个日期的每个日期上添加 6 个月；

=IF(M2="","",DATE(YEAR(M2)+0,MONTH(M2)+6,DAY(M2)+0))

查看任何结果日期是否等于或大于TODAY()；
如果是，则将“ALARM”放入列 O 中，然后通过过滤将此值作为标识符的行，将该列用作其他地方的标记。

=IF(today()>=X2,"ALARM","")

我想知道是否可以创建一个查询，其中 6 个月已经添加到 J 列中的值，并且可能，结果列表过滤 IF 列 J 中的值 [i] 大于或等于 @987654328 @。通过实现这一点，J 列将仅包含 Last N dates + 6 months 和 >= TODAY()；我检查过的所有示例似乎都使用日期作为过滤器。

【问题讨论】：

@player0 docs.google.com/spreadsheets/d/…
@player0 Sheet $Db_data
@player0 查找 AA 列
我猜你也想保持非警报状态？
@player0 实际上不是，只有在 ALARM 为 TRUE 的情况下

标签： google-sheets google-query-language

【解决方案1】：

=QUERY({FleetStatus!A1:D, ARRAYFORMULA(
 DATE(YEAR(FleetStatus!J1:J), MONTH(FleetStatus!J1:J)+6, DAY(FleetStatus!J1:J)))}, 
 "select Col1,Col5,'ALARM' 
  where Col1 is not null 
    and Col1 !='IVAN GUBKIN' 
    and Col1 !='VYACHESLAV TIKHONOV'
    and Col4 != 'L'
    and Col5 <=date '"&TEXT(TODAY(), "yyyy-mm-dd")&"' 
  label Col5'+6M', 'ALARM''Alarm'
  format Col5 'dd-mmm-yyyy'", 1)

【讨论】：

谢谢 - 非常感谢！
如何删除由上述 QUERY 创建的列 ALARM？ '选择 Col1、Col 5、'ALARM'
@AlexShevyakov 像这样：=QUERY({FleetStatus!A1:D, ARRAYFORMULA( DATE(YEAR(FleetStatus!J1:J), MONTH(FleetStatus!J1:J)+6, DAY(FleetStatus!J1:J)))}, "select Col1,Col5 where Col1 is not null and Col1 !='IVAN GUBKIN' and Col1 !='VYACHESLAV TIKHONOV' and Col4 != 'L' and Col5 <=date '"&TEXT(TODAY(), "yyyy-mm-dd")&"' label Col5'+6M' format Col5 'dd-mmm-yyyy'", 1)
谢谢您，给您带来的困扰很抱歉

【解决方案2】：

=QUERY({Sheet1!A1:A,
 ARRAYFORMULA(DATE(YEAR(Sheet1!J1:J), MONTH(Sheet1!J1:J)+6, DAY(Sheet1!J1:J)))}, 
 "select Col1,Col2,'ALARM' 
  where Col1 is not null 
    and Col2 >=date '"&TEXT(TODAY(), "yyyy-mm-dd")&"' 
  label Col2'ABCD', 'ALARM''alarm'
  format Col2 'dd-mmm-yyyy'", 1)

【讨论】：