Vlookup 找不到参考单元格答案

【问题标题】：Vlookup not able to find reference cellVlookup 找不到参考单元格
【发布时间】：2019-02-14 19:35:03
【问题描述】：

我正在使用 Google 表格查找公式，但返回的代码显示

“无法匹配'.25oz'”

工作表的链接在这里：
https://docs.google.com/spreadsheets/d/1K1Hb9xV8Ky51Vdiv0SG-zKOEH0ELPNBYwMWhDFfm4l0/edit#gid=168328825

我遇到错误的具体部分是“Master Cocktail”D5，它尝试搜索我的 Spirits 表或“Beer NA Bev”表。根据使用的盎司购买适当的价格。

我在单元格中使用的代码是：

=ArrayFormula(IF(C5="","",vlookup($B5,{'Beer NA Bev'!$A$63:$H$71;Spirits!$A$2:$I$325},MATCH($C5,{'Beer NA Bev'!$A$62:$K$62;Spirits!$A$3:$J$3},0),FALSE)))

【问题讨论】：

例如单元格 D5 应该从“Beer NA Bev”表行“Citrus, Limes”中提取价格。因此，如果 C5 =.25 盎司，那么它将在“Beer NA Bev”表中查找 0.25 盎司酸橙汁的价格

标签： google-sheets match importrange

【解决方案1】：

首先{'Beer NA Bev'!$A$63:$H$71; Spirits!$A$2:$I$325}
必须是：{'Beer NA Bev'!$A$63:$I$71; Spirits!$A$2:$I$325} 例如。相同数量的列
然后你可以放下整个MATCH并放在那里IFERROR下面会有IF和两个VLOOKUP（一个用于TRUE侧，一个用于FALSE侧）到区分啤酒和烈酒，因为两张纸上都有.25oz。然后您可以插入简单的IFS 来检查/搜索正确的.25oz 价格并返回主要VLOOKUP 的列号。
检查这个类似的问题：https://stackoverflow.com/a/54680420/5632629

类似这样的：

 IFERROR(IF(VLOOKUP(B5, 'Beer NA Bev'!$A$63:$I$71, 1, 0)<>"", IFS(C5=".25oz", 5, 
                                                                  C5=".5oz",  6, 
                                                                  C5=".75oz", 7, 
                                                                  C5="1oz",   8,
                                                                  C5="2oz",   9), ), 
         IF(VLOOKUP(B5, Spirits!$A$2:$I$325,       1, 0)<>"", IFS(C5="2oz",   4,
                                                                  C5="1.5oz", 5,
                                                                  C5="1oz",   6,
                                                                  C5=".75oz", 7,
                                                                  C5=".5oz",  8,
                                                                  C5=".25oz", 9), ))

整个公式是：

=ARRAYFORMULA(IF(C5="", "",
 VLOOKUP($B5, {'Beer NA Bev'!$A$63:$I$71;
                     Spirits!$A$2:$I$325},
 IFERROR(IF(VLOOKUP(B5, 'Beer NA Bev'!$A$63:$I$71, 1, 0)<>"", IFS(C5=".25oz", 5, 
                                                                  C5=".5oz",  6, 
                                                                  C5=".75oz", 7, 
                                                                  C5="1oz",   8,
                                                                  C5="2oz",   9), ), 
         IF(VLOOKUP(B5, Spirits!$A$2:$I$325,       1, 0)<>"", IFS(C5="2oz",   4,
                                                                  C5="1.5oz", 5,
                                                                  C5="1oz",   6,
                                                                  C5=".75oz", 7,
                                                                  C5=".5oz",  8,
                                                                  C5=".25oz", 9), )), 0)))

【讨论】：

这样吗？ =if($A5="NAProduce",vlookup($B5,'Beer NA Bev'!$A$63:$A$71),Vlookup($B5,Spirits!$A$2:$A$325),IFS($C5 ='.25oz',5, $C5='.5oz,6, $C5='.75oz',7, $C5=''1oz',8 $C5="'2oz',9),0), ))"))