使用单独的库存和发行表在谷歌表中维护库存表

【问题标题】：Maintain a stock sheet in google sheets with seperate Inventory and Issuance sheets使用单独的库存和发行表在谷歌表中维护库存表
【发布时间】：2020-04-13 09:38:34
【问题描述】：

我有两张表，分别是库存盘点和发行盘点，它们都有样品编号和数量。我想维护第三张库存表，其中将显示样品编号、库存计数、发行计数和库存计数。库存盘点就是库存盘点 - 发行盘点。

库存和发行计数表将自动更新。

库存盘点和出库单中的样品编号可能排列方式不同，而且库存盘点中可能存在的一些样品可能不在出库单中，因此其在库存单中的出库数必须为 0。

我已将链接粘贴到与我的用例类似的参考表中。任何帮助将不胜感激。提前致谢！

https://docs.google.com/spreadsheets/d/1UDlCzA1WDkIWDNoEffihSH2rKegKHciSP1kqp_QJ-kY/edit?usp=sharing

【问题讨论】：

标签： excel google-sheets google-sheets-formula

【解决方案1】：

您可以将数组公式放在标题中，这将满足您的要求。

所有唯一的样本编号：

={
  "Sample Number";
  SORT(UNIQUE(
    {
      UNIQUE(FILTER(Issuance!A2:A, Issuance!A2:A <> ""));
      UNIQUE(FILTER(Inventory!A2:A, Inventory!A2:A <> ""))
    }
  ))
}

库存盘点：

={
  "Inventory Count";
  ARRAYFORMULA(IF(B2:B = "", "", COUNTIF(Inventory!A2:A, B2:B)))
}

发行计数：

={
  "Issuance Count";
  ARRAYFORMULA(IF(B2:B = "", "", COUNTIF(Issuance!A2:A, B2:B)))
}

库存：

={
  "Stock";
  ARRAYFORMULA(IF(B2:B = "", "", C2:C - D2:D))
}

看看你的样张，这一切都在那里。

【讨论】：