【问题标题】：Multiple IF statements between number ranges数字范围之间的多个 IF 语句
【发布时间】：2014-08-31 00:19:49
【问题描述】：

我正在尝试设置一个在数字范围之间包含多个 IF 语句的公式，但我看到了错误：

公式解析错误

这是论坛：

=IF((AND(A2>0,A2<500),"Less than 500",
 If(AND(A2>=500,A2<1000),"Between 500 and 1000"),
 If(AND(A2>=1000,A2<1500),"Between 1000 and 1500"),
 If(AND(A2>=1500,A2<2000),"Between 1500 and 2000")))

【问题讨论】：

标签： if-statement google-sheets google-sheets-formula

【解决方案1】：

由于嵌套的 IF，这有点棘手，但这是我的答案（已在 Google 电子表格中确认）：

=IF(AND(A2>=0,    A2<500),  "Less than 500", 
 IF(AND(A2>=500,  A2<1000), "Between 500 and 1000", 
 IF(AND(A2>=1000, A2<1500), "Between 1000 and 1500", 
 IF(AND(A2>=1500, A2<2000), "Between 1500 and 2000", "Undefined"))))

【讨论】：

【解决方案2】：

我建议使用vlookup 函数来获得最近的匹配。

第 1 步

准备数据范围并命名：'numberRange'：

选择范围。转到菜单：数据 → 命名范围... → 定义新的命名范围。

第 2 步

使用这个简单的公式：

=VLOOKUP(A2,numberRange,2)

这样您可以省略错误，并轻松纠正结果。

【讨论】：

【解决方案3】：

基于VLOOKUP的独立单细胞解决方案

美国语法：

=IFERROR(ARRAYFORMULA(IF(LEN(A2:A),
        IF(A2:A>2000, "More than 2000",VLOOKUP(A2:A,
 {{(TRANSPOSE({{{0;   "Less than 500"},
               {500;  "Between 500 and 1000"}},
              {{1000; "Between 1000 and 1500"},
               {1500; "Between 1500 and 2000"}}}))}}, 2)),)), )

欧盟语法：

=IFERROR(ARRAYFORMULA(IF(LEN(A2:A);
        IF(A2:A>2000; "More than 2000";VLOOKUP(A2:A;
 {{(TRANSPOSE({{{0;   "Less than 500"}\
               {500;  "Between 500 and 1000"}}\
              {{1000; "Between 1000 and 1500"}\
               {1500; "Between 1500 and 2000"}}}))}}; 2));)); )

替代方案：https://webapps.stackexchange.com/questions/123729/

【讨论】：

【解决方案4】：

比公认的 A 短，易于扩展，地址 0 及以下：

=if(or(A2<=0,A2>2000),"?",if(A2<500,"Less than 500","Between "&500*int(A2/500)&" and "&500*(int(A2/500)+1)))

【讨论】：

【解决方案5】：

对于连续的多个条件，Google 表格提供了更高效、更易读的 IFS 公式：

   =IFS( 
     A2<500,  "Less than 500", 
     A2<1000, "Between 500 and 1000", 
     A2<1500, "Between 1000 and 1500", 
     A2<2000, "Between 1500 and 2000" )

您也可以为小于 0 或大于 2000 的案例添加条件，但这基本上是您所要求的。

【讨论】：