从 GoogleFinance 获取特定日期的汇率答案

【问题标题】：Get exchange rate on a specific date from GoogleFinance从 GoogleFinance 获取特定日期的汇率
【发布时间】：2017-11-15 14:59:37
【问题描述】：

我无法在特定日期停止 googlefinance 功能以使用“那个”特定汇率将货币从英镑转换为欧元。

这是我的公式：=Finance!B4*GOOGLEFINANCE("CURRENCY:GBPEUR","price",date(2017,15,11))

这是错误：When evaluating GOOGLEFINANCE, the query for the symbol: 'CURRENCY:GBPEUR' returned no data.

我查看了关于 SO 的其他解决方案，但无济于事。实际上，我已将 "date" 和 "price" 从其他解决方案添加到我的公式中。像这样：-Solution 1

【问题讨论】：

【解决方案1】：

首先，date(2017,15,11) 表示一年中的第 15 个月的第 11 天，因此您需要交换月份和日期。

其次，历史数据查询，如

=GOOGLEFINANCE("CURRENCY:GBPEUR", "price", date(2017,11,15))

返回一个包含列和标题的表格。

Date                Close
11/15/2017 23:58:00 1.1163

从你使用这个公式的方式来看，我看到你只想要汇率。将函数包裹在index(..., 2, 2) 中以获取第二行的第二个单元格。

=index(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", date(2017,11,15)), 2, 2)

【讨论】：

@user6655984 如果我需要使用引用而不是日期来调用日期怎么办？说 =index(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", date(A5)), 2, 2)???
@AlexShevyakov 应该是：=INDEX(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", A5), 2, 2)

【解决方案2】：

为了确保它是已知的，, 运算符未在今天的 Google 表格中使用，因此避免解析器错误的正确表达式是（在您的情况下）：

=index(GOOGLEFINANCE("CURRENCY:GBPEUR"; "price"; date(2017;11;15)); 2; 2)

【讨论】：

【解决方案3】：

这是我的这个公式的版本。

B3 应该是有效日期。

=index(GOOGLEFINANCE("CURRENCY:USDCNY", "price", B3), 2, 2)

附言。我不确定为什么，但是当我指定 2018 年 12 月 15 日时，公式显示错误。所有其他日期都是正确的。

【讨论】：

【解决方案4】：

您的问题是（曾经）您试图强制获取不存在的第 15 个月的数据。 DATE 的语法是：

=DATE(YEAR(), MONTH(), DAY())

所以完整的公式应该是：

=Finance!B4*INDEX(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", DATE(2017, 11, 15)), 2, 2)

替代方案是：

=Finance!B4*INDEX(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", "15/11/2014"), 2, 2)

=Finance!B4*INDEX(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", DATEVALUE("15/11/2014")), 2, 2)

=Finance!B4*INDEX(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", A1), 2, 2)

其中 A1 包含有效日期

【讨论】：

【解决方案5】：

在 Google 表格中，我是这样做的，使用分号：

=index(googlefinance("currency:USDNOK";"price";G11);2;2)

G11 是我的包含日期的单元格。它似乎为我完成了这项工作。我在 G11 中使用今天的日期对其进行了测试，并得到了与今天汇率的简化版本相同的结果：

=googlefinance("currency:USDNOK")

【讨论】：

【解决方案6】：

2018 年 12 月 15 日是星期日 - 因此出现错误。您可以添加 -2 或 +2，因为该错误也会在星期六弹出。我更喜欢 -2

【讨论】：

【解决方案7】：

:D 没有任何效果。无论我从单元格中插入什么日期或地址，无论我声明什么货币对，我从单元格中插入什么价格或地址，有或没有索引 → 它都会返回“分析错误”。当这种情况发生时，我喜欢它。

【讨论】：