如何获取 Google 表格中列中的最后一个数值？答案

【问题标题】：How can I get the last numerical value value in a column in Google Sheets?如何获取 Google 表格中列中的最后一个数值？
【发布时间】：2021-03-14 22:07:39
【问题描述】：

我需要找到列中的最后一个数字值。我使用这个公式来获取 G 列中的最后一个值，但我做了一些更改，它不再起作用：=INDEX(G:G, COUNTA(G:G), 1)。我的专栏现在看起来像这样：

645
2345
4674.2345
123.1
“-”
“-”
“-”

...公式返回“-”。我希望它返回 123.1。我该怎么做？

【问题讨论】：

“-”后面有数字吗？即“-”是否总是在数据的末尾？
单元格是一个连字符，就是这样。我不知道如何在不做一些格式化的情况下在帖子中添加一个破折号......（单元格字面意思是 - ）

标签： google-sheets google-sheets-formula

【解决方案1】：

有很多方法可以解决这个问题。这是其中之一：

=QUERY(FILTER({G:G,ROW(G:G)},ISNUMBER(G:G)),"Select Col1 ORDER BY Col2 Desc LIMIT 1")

FILTER 在第一列中创建一个仅包含 G 中数值的虚拟数组，并在第二列中创建这些数值所在的行。

QUERYreturns 按行号翻转顺序并仅返回第一列中的新顶部值（最终成为原始范围内的最后一个数值）。

但是，如果您的数值从 G1 开始，并且在您开始在单元格中添加连字符的位置之前只有个数值，您可以像这样更改原始公式：

=INDEX(G:G,COUNT(G:G))

这会起作用，因为COUNT 只计算数值，而COUNTA 计算所有非空值（包括错误顺便说一句）。

【讨论】：

我最终使用了第二个函数，即 INDEX，因为我的列在连字符之前只有数值。由于某种原因，我确实必须将其设为 =INDEX(G:G, SUM(COUNT(G:G), 1), 1) ，因为它得到的是倒数第二个数值而不是最后一个数值。谢谢！
这告诉我你在 G1 中有一个标题（不会被 COUNT 计算在内）。
是的，我愿意，这是有道理的。将计数加 1 即可平衡。
您可以通过将公式中的范围从 G:G 更改为 G2:G 来实现相同的效果（并有一个更准确地反映正在发生的事情的公式）。

【解决方案2】：

不要从已接受的答案中拿走任何东西，但我最近一直在研究与this for the never-ending last row discussion 相关的问题，并认为我会分享一些潜在的类似解决方案。这些想法的灵感来自似乎更频繁出现的谷歌表格数组问题模式。我也有意使用不同的方式来做同样的事情，只是为了给人们一些想法（即左和正则表达式）。

最后一行是...

号码：=max(filter(row(G:G),isnumber(G:G)))
文字：=max(filter(row(G:G),isText(G:G)))
一个错误：=max(filter(row(G:G),iserror(G:G)))
在0 下：=max(filter(row(G:G),G:G<0))
也存在于column D:=max(filter(row(G:G),ISNUMBER(match(G:G,D:D,0))))
非空白：=max(filter(row(A:A),NOT(ISBLANK(A:A))))
以ab开头：=max(filter(row(G:G),left(G:G,2)="ab"))
包含字符!：=max(filter(row(G:G),isnumber(Find("!",G:G))))
以数字开头：=max(filter(row(G:G),REGEXMATCH(G:G,"^\d")))
仅包含字母：=max(filter(row(G:G),REGEXMATCH(G:G,"^[a-zA-Z]+$")
最后四位为大写：=Max(filter(row(G:G),REGEXMATCH(G:G,"[A-Z]{4}$")))

要获得实际的值（我意识到这是真正的问题），只需将索引函数包裹在Max 函数周围。所以对于这个问题，一个解决方案可能是：

=Index(G:G,max(filter(row(G:G),isnumber(G:G))))

【讨论】：