Delphi XE4检测TListGroups之间的项目切换

Question

我已经使用 Delphi XE4 一个星期了，我刚刚发现了新的TListGroups 功能。很容易设置TlistItem 的GroupID 在组之间轻松切换/移动。现在，我想要一个在TListItem 离开组和/或TlistItem 进入组时立即调用的过程。我正在寻找这样的东西：

procedure TForm1.ListView1On(Before/After)ListGroupEnter(Sender: TObject; Item: TListItem);
begin
 // Do some stuff here like...
 // AllowedToDraw := TRUE/FALSE
 // I/O Code...
 // etc...
end;

procedure TForm1.ListView1On(Before/After)ListGroupLeave(Sender: TObject; Item: TListItem);
begin
 // Do some stuff here like...
 // This might be replaceable with OnDeletion...
 // I/O Code...
end;

这里的主要问题是如果你设置了GroupID属性来检测各个组之间的切换。 那么，一旦您更改/设置GroupID 属性，是否有任何东西可以检测到开关？

Answer 1

TListItem.GroupID 属性设置器向TListView's HWND 发送LVM_SETITEM 消息。您可以将TListView 子类化并在TListView 处理它之前拦截该消息，例如：

const
  APPWM_LISTVIEW_CHECKGROUP = WM_APP + 100;

var
  PrevLVWndProc: TWndMethod = nil;

procedure TForm1.FormCreate(Sender: TObject);
begin
  PrevLVWndProc := ListView1.WindowProc;
  ListView1.WindowProc := LVWndProc;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  ListView1.WindowProc := PrevLVWndProc;
end;

procedure TForm1.LVWndProc(var Message: TMessage);
var
  LVItem: PLVItem;
  ListItem: TListItem;
begin
  case Message.Msg of
    LVM_SETITEM:
    begin
      LVItem := PLVItem(Message.LParam);
      if (LVItem^.mask and LVIF_GROUPID) <> 0 then
      begin
        ListItem := ListView1.Items[LVItem.iItem];

        if ListItem.GroupID <> LVItem.iGroupID then
        begin
          if ListItem.GroupID >= 0 then
            ListView1GroupLeave(ListView1, ListItem);

          PrevLVWndProc(Message);

          // this gives the TListItem time to actually update itself
          PostMessage(ListView1.Handle, APPWM_LISTVIEW_CHECKGROUP, 0, LVItem.iItem);

          Exit;
        end;
      end;
    end;
    APPWM_LISTVIEW_CHECKGROUP:
    begin
      ListItem := ListView1.Items[Message.LParam];
      if ListItem.GroupID >= 0 then
        ListView1GroupEnter(ListView1, ListItem);
      Exit;
    end;
  end;

  PrevLVWndProc(Message);
end;

procedure TForm1.ListView1GroupLeave(Sender: TObject; Item: TListItem);
begin
  // Item is about to leave from its current GroupID ...
end;

procedure TForm1.ListView1GroupEnter(Sender: TObject; Item: TListItem);
begin
  // Item has entered into its current GroupID ...
end;