在单元格中使用带有搜索条件的 Countif 通配符

Question

我有一组数据单元格 B1:C5，其中包含字母数字字符及其旁边的数据的混合测试。我正在尝试为单元格 B8:C10 创建一个公式，该公式将解析 A2:C5 中的数据，并使用 CountIfS 函数计算与样本和值 1 匹配的单元格数。某些数据会出现问题其测试名称包括多个样本的平均值。我希望对这些测试中的每个样本进行计数。这是excel表的可视化：

Input
+----+------------+---------+---------+
|    |     A      |    B    |    C    |
+----+------------+---------+---------+
|  1 | Test       | Value 1 | Value 2 |
|  2 | 1          | TRUE    | ...     |
|  3 | 14A        | FALSE   | ...     |
|  4 | 1, 14A Avg | FALSE   | ...     |
|  5 | 1, 53 Avg  | TRUE    | ...     |
+----+------------+---------+---------+

Current Output
+----+------------+---------+---------+
|    |     A      |    B    |    C    |
+----+------------+---------+---------+
|  7 | Specimen   | TRUE    | FALSE   |
|  8 | 1          | 1       | 2       |
|  9 | 14A        | 0       | 2       |
| 10 | 53         | 1       | 0       |
+----+------------+---------+---------+

Desired Output
+----+------------+---------+---------+
|    |     A      |    B    |    C    |
+----+------------+---------+---------+
|  7 | Specimen   | TRUE    | FALSE   |
|  8 | 1          | 2       | 1       |
|  9 | 14A        | 0       | 2       |
| 10 | 53         | 1       | 0       |
+----+------------+---------+---------+

我一直在 B8 单元格中使用以下公式：（为了便于阅读，忽略 $）

=COUNTIFS(A1:A5, "*" & A8 & "*", B1:B5, B7)

我遇到的问题来自公式如何评估样本 1；它不计算第 2 行中的测试 1，而是计算第 3 行中的测试 14A。我找到了一个解决方案，该解决方案包括在平均测试中的每个样本的末尾放置一个逗号并使用以下公式：

=COUNTIFS(A2:A5, A8, B2:B5, B7) + COUNTIFS(A2:A5, "*" & A8 & ",*", B2:B5, B7)

使用此方法的问题是我必须更改平均测试的名称（我想避免的解决方案）以及我将要评估的所有其他值，这将使公式非常长而笨重。我想知道是否有一种更简单的方法可以将上面的两个 CountIfS 合并为一个，而无需操作测试或样本的名称。

Answer 1

您将需要使用 SUMPRODUCT() 和其他一些公式来解析数据：

=SUMPRODUCT((ISNUMBER(SEARCH(" " & $A8 & " "," " & SUBSTITUTE($A$2:$A$5,","," ") & " ")))*($B$2:$B$5=B$7))

通过将, 更改为空格并在字符串的前后添加空格，我们还可以用空格将搜索值括起来，以确保我们正在查找完整条目而不是部分。

然后SUMPRODUCT每次在每个字符串中找到完整值并且Value one等于标题时计数。