Perl 6 的 eof 放弃得太快了吗？

Question

在 Perl 5 中，我可以检查标准输入是否打开并从中读取一行。

for (;;) {
    last if eof(STDIN);
    print "Got line " . readline(STDIN);
    }

当我运行它并输入一行输入时，它会读取该行并在继续之前完成它的工作。程序不关心是否有长时间的停顿：

$ perl print-stdin.pl
this
Got line this
is
Got line is
a
Got line a
line
Got line line

如果我在 Perl 6 (Rakudo 2017.07) 中做同样的事情，程序会立即停止：

use v6;
loop {
    last if $*IN.eof;
    put "Got line " ~ $*IN.get;
    }

我真的很喜欢Supply，它可以在它到达时给我一行输入（可能来自一个缓慢输出行且有长时间停顿的程序），但我一直支持这个简单的问题。我没有找到执行此操作的内置方法（这对于如此常见的任务来说有点令人惊讶）。

Answer 1

它似乎在最新版本上效果更好。
尽管您所写的内容具有竞争条件，因为在调用 .eof 后可以关闭输入。这意味着它可能在 .get 被阻止时发生，因此它将返回 Nil。这将导致抛出警告，并打印额外的Got line 。

最好只使用来自.lines的迭代器

for $*IN.lines { put "Got line $_" }

或者使用.get的返回值来判断输入何时关闭。

loop {
  with $*IN.get {
    put "Got line $_"
  } else {
    last
  }
}

---

如果您想从输入行中获取供应：

$*IN.lines.Supply

react {
  start whenever $*IN.lines.Supply {
    put "Got line $_";
    LAST done; # finish the outer ｢react｣ block when this closes
  }
  whenever Supply.interval(1) {
    put DateTime.now.hh-mm-ss
  }
}

22:46:33
22:46:34
a
Got line a
22:46:35
22:46:36
b
Got line b
22:46:37
22:46:38
c
Got line c
22:46:39
22:46:40
d
Got line d
22:46:41
22:46:42
^D               # represents Ctrl+D

上面需要start，因此它不会阻止Supply.interval(1) 供应正常启动。

---

如果由于某种原因无法执行上述操作，您可以像这样创建供应：

my \in-supply = supply {

  # ｢await start｣ needed so this won't block other things on this thread.

  await start loop {
    with $*IN.get { # defined (so still open)

      emit $_

    } else {        # not defined (closed)

      done;         # stop the Supply

      # last        # stop this loop (never reached)

    }
  }
}

react {
  whenever in-supply {
    put "Got line $_";
    LAST done # finish the outer ｢react｣ block when this closes
  }
  whenever Supply.interval(1) {
    put DateTime.now.hh-mm-ss
  }
}