如何在 AHK Windows 10 中生成字符串的 MD5？答案

【问题标题】：How do I generate MD5 of a string in AHK Windows 10?如何在 AHK Windows 10 中生成字符串的 MD5？
【发布时间】：2016-01-06 11:05:35
【问题描述】：

我尝试了来自 https://github.com/acmeism/RosettaCodeData/blob/master/Task/MD5/AutoHotkey/md5-1.ahk 的代码，确实适用于 Windows 7：

data := "abc"
MsgBox % MD5(data,StrLen(data)) ; 900150983cd24fb0d6963f7d28e17f72

MD5( ByRef V, L=0 ) {
 VarSetCapacity( MD5_CTX,104,0 ), DllCall( "advapi32\MD5Init", Str,MD5_CTX )
 DllCall( "advapi32\MD5Update", Str,MD5_CTX, Str,V, UInt,L ? L : VarSetCapacity(V) )
 DllCall( "advapi32\MD5Final", Str,MD5_CTX )
 Loop % StrLen( Hex:="123456789ABCDEF0" )
  N := NumGet( MD5_CTX,87+A_Index,"Char"), MD5 .= SubStr(Hex,N>>4,1) . SubStr(Hex,N&15,1)
Return MD5
}

但是，现在某些 dll 调用必须不起作用，因为它确实不在 windows 10 中返回正确的值。例如，给定的代码 sn-p 返回 70350F6027BCE3713F6B76473084309B 而不是 @ 987654326@。我还尝试使用管理员权限运行它。不知道这背后的原因是什么。由于某种原因，我无法直接访问 advapi32 dll 中的 MD5 函数。

我应该怎么做才能获得正确的 MD5 哈希？

【问题讨论】：

我当前的解决方法：从fourmilab.ch/md5 和Run %comspec% /C ""%A_WorkingDir%\md5.exe" -d"%MY_STRING%" > "%A_WorkingDir%\tmp.txt"", %A_WorkingDir% 执行exe，然后读取tmp.txt 的文件内容（嵌入循环并在之后进行文件删除）
在 CryptCreateHash 文档中没有提到它在 Windows 10 上不可用。所以也许你应该这样做：msdn.microsoft.com/en-us/library/windows/desktop/… 是 .netFramework 的 MD5Init/MD5Update/MD5Final 部分还是 dos/did它默认带有Windows？我找不到它的文档。
如果所有这些都不起作用，可能值得尝试获取一个 javascript 库，将其放入脚本对象并在您的代码中使用它。我不确定它是否可以处理二进制数据......
我真的不知道。但我认为是标准的windows安装内容。

标签： md5 autohotkey

【解决方案1】：

不确定它是否可以在 Windows 10 上运行，但在 Rosetta 代码上发布了本机版本：

http://rosettacode.org/wiki/MD5#Native_implementation

来源：AutoHotkey forum by Laszlo

; GLOBAL CONSTANTS r[64], k[64] 
r =  12, 17, 22,  7, 12, 17, 22,  7, 12, 17, 22,  7, 12, 17, 22 
, 5,  9, 14, 20,  5,  9, 14, 20,  5,  9, 14, 20,  5,  9, 14, 20 
, 4, 11, 16, 23,  4, 11, 16, 23,  4, 11, 16, 23,  4, 11, 16, 23 
, 6, 10, 15, 21,  6, 10, 15, 21,  6, 10, 15, 21,  6, 10, 15, 21 
StringSplit r, r, `, 
r0 := 7 
Loop 64 
   i := A_Index-1, k%i% := floor(abs(sin(A_Index)) * 2**32) 

; TEST CASES 
MsgBox % MD5(x:="", 0) ; d41d8cd98f00b204e9800998ecf8427e 
MsgBox % MD5(x:="a", StrLen(x)) ; 0cc175b9c0f1b6a831c399e269772661 
MsgBox % MD5(x:="abc", StrLen(x)) ; 900150983cd24fb0d6963f7d28e17f72 
MsgBox % MD5(x:="message digest", StrLen(x)) ; f96b697d7cb7938d525a2f31aaf161d0 
MsgBox % MD5(x:="abcdefghijklmnopqrstuvwxyz", StrLen(x))
; c3fcd3d76192e4007dfb496cca67e13b 
MsgBox % MD5(x:="ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789", StrLen(x))
; d174ab98d277d9f5a5611c2c9f419d9f 
MsgBox % MD5(x:="12345678901234567890123456789012345678901234567890123456789012345678901234567890", StrLen(x))
; 57edf4a22be3c955ac49da2e2107b67a 
MsgBox % MD5(x:="The quick brown fox jumps over the lazy dog", StrLen(x))
; 9e107d9d372bb6826bd81d3542a419d6 
MsgBox % MD5(x:="The quick brown fox jumps over the lazy cog", StrLen(x))
; 1055d3e698d289f2af8663725127bd4b 

MD5(ByRef Buf, L) { ; Binary buffer, Length in bytes 
   Static P, Q, N, i, a,b,c,d, t, h0,h1,h2,h3, y = 0xFFFFFFFF 

   h0 := 0x67452301, h1 := 0xEFCDAB89, h2 := 0x98BADCFE, h3 := 0x10325476 

   N := ceil((L+9)/64)*64 ; padded length (100..separator, 8B length) 
   VarSetCapacity(Q,N,0)  ; room for padded data 
   P := &Q ; pointer 
   DllCall("RtlMoveMemory", UInt,P, UInt,&Buf, UInt,L) ; copy data 
   DllCall("RtlFillMemory", UInt,P+L, UInt,1, UInt,0x80) ; pad separator 
   DllCall("ntdll.dll\RtlFillMemoryUlong",UInt,P+N-8,UInt,4,UInt,8*L) ; at end: length in bits < 512 MB 

   Loop % N//64 { 
      Loop 16 
         i := A_Index-1, w%i% := *P | *(P+1)<<8 | *(P+2)<<16 | *(P+3)<<24, P += 4 

      a := h0, b := h1, c := h2, d := h3 

      Loop 64 { 
         i := A_Index-1 
         If i < 16 
             f := (b & c) | (~b & d), g := i 
         Else If i < 32 
             f := (d & b) | (~d & c), g := 5*i+1 & 15 
         Else If i < 48 
             f := b ^ c ^ d,          g := 3*i+5 & 15 
         Else 
             f := c ^ (b | ~d),       g :=  7*i  & 15 

         t := d, d := c, c := b 
         b += rotate(a + f + k%i% + w%g%, r%i%) ; reduced to 32 bits later 
         a := t 
      } 

      h0 := h0+a & y, h1 := h1+b & y, h2 := h2+c & y, h3 := h3+d & y 
   } 
   Return hex(h0) . hex(h1) . hex(h2) . hex(h3) 
} 

rotate(a,b) { ; 32-bit rotate a to left by b bits, bit32..63 garbage 
   Return a << b | (a & 0xFFFFFFFF) >> (32-b) 
} 

hex(x) {      ; 32-bit little endian hex digits 
   SetFormat Integer, HEX 
   x += 0x100000000, x := SubStr(x,-1) . SubStr(x,8,2) . SubStr(x,6,2) . SubStr(x,4,2) 
   SetFormat Integer, DECIMAL 
   Return x 
}

【讨论】：

谢谢，但不幸的是，这段代码甚至返回abc的另一个哈希：C22D46..etc。我使用了你的代码和测试用例
奇怪，我不在 Windows 10 上，所以我无能为力。
该代码似乎已经过时了。它甚至不使用数组。也许它只需要为 AHK_L 重写。

【解决方案2】：

这些来自 jNizM 的哈希函数似乎可以工作：https://www.autohotkey.com/boards/viewtopic.php?f=6&t=21

对于 MD5：

md5(string)     ;   // by SKAN | rewritten by jNizM
{
    hModule := DllCall("LoadLibrary", "Str", "advapi32.dll", "Ptr")
    , VarSetCapacity(MD5_CTX, 104, 0), DllCall("advapi32\MD5Init", "Ptr", &MD5_CTX)
    , DllCall("advapi32\MD5Update", "Ptr", &MD5_CTX, "AStr", string, "UInt", StrLen(string))
    , DllCall("advapi32\MD5Final", "Ptr", &MD5_CTX)
    loop, 16
        o .= Format("{:02" (case ? "X" : "x") "}", NumGet(MD5_CTX, 87 + A_Index, "UChar"))
    DllCall("FreeLibrary", "Ptr", hModule)
    StringLower, o,o
    return o
}

【讨论】：