AT&T x86 汇编中计算最大值的函数

Question

我正在尝试编写这个名为 maximum 的函数，它将从数字列表中返回最大值，我想使用可以指示从哪里开始的标签。当地址（我用于计算下一个值在哪里）超过列表时，函数将跳转到循环的末尾。

不幸的是，在组装程序并运行它后，我得到了分段错误。

我要求找出我的代码中的错误。我尝试使用 GDB 调试器，但还是不行。

.section .data
list_1:
 .long 5,3,6,2,7,78
list_2:
 .long 33,23,52,6,7,89,22,33,6
list_3:
 .long 22,33,10,45,6,34
end_list_3:

 .section .text

 .globl _start
 .globl maximum
_start:

 pushl list_2
 pushl list_1
 call maximum
 addl $8, %esp
 movl %eax, %ebx


 mov $1, %eax
 int $0x80
                        #maximum function: 1 param - location of first value
                        #                  2 param - location of last value+4
 .type maximum STT_FUNC
maximum:
 pushl %ebp
 movl %esp, %ebp

 movl 8(%ebp),%ebx      # %ebx = location of first value
 movl 12(%ebp), %ecx    # %ecx location of last value + 4

 movl (%ebx), %eax      # %eax will store current highest value

 movl $0, %esi          # %esi will be our index

start_loop:
 incl %esi
 lea (%ebx,%esi,4), %edx
 cmpl %edx, %ecx
 je exit_loop
 movl (%ebx,%esi,4), %edi       #%edi is a current examined value
 cmpl %eax, %edi
 cmovg %edi, %eax
 jmp start_loop
exit_loop:

 movl %ebp, %esp
 popl %ebp
 ret

Answer 1

问题在于推送参数，我想推送标签地址但正在使用：

pushl   list_2
pushl   list_1

list_1 和 list_2 被视为将被压入堆栈的值的地址，因此这是压入内存源操作数而不是立即数。

改为：

pushl   $list_2
pushl   $list_1

在这个小改动之后，程序按计划运行，现在这两条指令直接推送地址：list_1 和 list_2，这正是我想要的。

谢谢@Jérôme Richard 和@Jester。

Answer 2

您可以使用调试器轻松找到原因。我建议你使用 gdb（尤其是使用 layout asm 和 ni 命令）。

段错误位于这一行：

    mov (%ebx), %eax

这是正常的，因为 ebx 中存储的值是整数 (5) 而不是有效指针。 您可能想在以下说明中使用 lea 而不是 movl：

    movl 8(%ebp),%ebx      # %ebx = location of first value
    movl 12(%ebp), %ecx    # %ecx location of last value + 4