条件跳转未按 NASM 的预期工作

Question

我正在尝试编写一个执行以下操作的程序：

1. 在bx 寄存器中存储一个整数
2. 如果bx寄存器中存储的值小于等于4，则将A复制到al寄存器中
3. 如果bx寄存器中存储的值大于10，则将B复制到al寄存器中
4. 如果这两个条件都不成立，请将C 复制到al 寄存器中
5. 输出al寄存器的值

这是我写的程序：

section .data

section .text
    global _start
    
    _start:
        mov bx, 2
        
        cmp bx, 4
        jle copy_a
        cmp bx, 10
        jg copy_b
        mov al, 'C'
        
        copy_a:
            mov al, 'A'
            
        copy_b:
            mov al, 'B'
            
        mov byte [esp], al   ;push al
        mov eax, 0x04
        mov ebx, 0x01
        mov ecx, esp         ;esp points to the character to be printed
        mov edx, 0x01
        int 0x80
            
        mov eax, 0x01
        mov ebx, 0x00
        int 0x80

无论我将bx 的值更改为什么，它总是输出B

Answer 1

你必须添加一个跳转：

section .text
    global _start
    
    _start:
        mov bx, 2
        
        cmp bx, 4
        jle copy_a
        cmp bx, 10
        jg copy_b
        mov al, 'C'
        
        copy_a:
            mov al, 'A'
            jmp continue
        copy_b:
            mov al, 'B'

        continue:     
            mov byte [esp], al   ;push al
            mov eax, 0x04
            mov ebx, 0x01
            mov ecx, esp         ;esp points to the character to be printed
            mov edx, 0x01
            int 0x80    
            mov eax, 0x01
            mov ebx, 0x00
            int 0x80

你必须添加这个跳转，否则，处理器只会看到：

mov al, 'A'
mov al, 'B'

处理器将首先将'A' 移动到al，然后是'B''。这导致al 始终为B。

此外，如果没有任何条件为真，您忘记添加移动。 (bx > 4 && bx <= 10) 编辑： 要添加第三个条件，请尝试以下操作：

section .text
    global _start
    
    _start:
        mov bx, 2
        
        cmp bx, 4
        jle copy_a
        cmp bx, 10
        jg copy_b
        mov al, 'C'
        jmp continue ;Here.
        copy_a:
            mov al, 'A'
            jmp continue
        copy_b:
            mov al, 'B'

        continue:     
            mov byte [esp], al   ;push al
            mov eax, 0x04
            mov ebx, 0x01
            mov ecx, esp         ;esp points to the character to be printed
            mov edx, 0x01
            int 0x80    
            mov eax, 0x01
            mov ebx, 0x00
            int 0x80