组装 x86 FPU - 堆栈混乱

Question

我正在尝试理解 FPU，但我很困惑。问题是我从here 了解到，FPU 有自己的堆栈。但例如在这段代码（NASM）中：

global _main

extern _printf

section .data
    hellomessage db `Hello World!\n`, 10, 0
    numone dd 1.2
    digitsign db '%f', 0xA, 0

section .text
_main:
    ;Greet the user
    push hellomessage
    call _printf
    add esp,4

    sub esp, 8

    fld dword[numone]
    fstp qword[esp]

    push digitsign
    call _printf
    add esp, 12
    ret

我必须让sub esp, 8 行为double“腾出空间”，否则程序会崩溃。但是通过这样做，我改变了“常规堆栈”的指针，这对我的两个独立堆栈的想法没有意义。

我确定我不明白某事，但我不知道这是什么。

Answer 1

x87 加载/存储使用与其他所有操作相同的内存地址。 x87 堆栈是寄存器 st0..st7，根本不是内存。

有关 x87 寄存器堆栈的详细信息，请参阅 SIMPLY FPU: Chap. 1 Description of FPU Internals。

fstp qword[esp] 将 8 个字节存储到常规调用堆栈，就像 mov [esp], eax / mov [esp+4], edx 会做的那样。 寻址模式在与 x87 加载/存储指令一起使用时不会改变含义！即您的进程只有一个地址空间。

---

因此，如果您删除sub esp, 8，您的fstp 将覆盖您的返回地址。

然后在函数结束时，add esp, 12 将留下 esp 指向上方 8 个字节，因此ret 会将一些垃圾弹出到 EIP 中，然后在尝试从该错误地址获取代码时出现段错误，或者那里的字节解码为段错误的指令。

在main 的返回地址上方，您会找到argc，然后是char **argv。它是指向指针数组的指针，因此将其用作返回地址意味着您将指针 values 作为代码执行。 （如果我猜对了。）

使用调试器查看单步时寄存器和内存会发生什么变化。

---

请注意，add esp,4 / sub esp, 8 有点傻。 add esp, +4 - 8（即add esp, -4）将是一种自我记录的方式，只需一条指令即可。

Answer 2

FPU 有一个“寄存器堆栈”（而不是 RAM 中的堆栈）。

基本上；有 8 个寄存器（我们称它们为 FPU_R0、FPU_R1、...、FPU_R7）和 8 个名称（假设它们是 st0、st1、...、st7） ，并且有一个“FPU 堆栈顶部”值来确定哪个名称用于哪个寄存器。

您可以将新值压入 FPU 寄存器堆栈。例如：

    fld qword [A]     ;st0 = FPU_R7 = A
    fld qword [B]     ;st0 = FPU_R6 = B, st1 = FPU_R7 = A
    fld qword [C]     ;st0 = FPU_R5 = C, st1 = FPU_R6 = B, st2 = FPU_R7 = A

您可以从 FPU 寄存器堆栈中弹出值。例如：

                      ;st0 = FPU_R5 = C, st1 = FPU_R6 = B, st2 = FPU_R7 = A
    fstp qword [C]    ;st0 = FPU_R6 = B, st1 = FPU_R7 = A
    fstp qword [B]    ;st0 = FPU_R7 = A
    fstp qword [A]