echo 与管道一起使用时会增加空间

Question

在回答 this 问题时，我发现了一些我无法解释的奇怪行为

for /f "delims=" %a in ('(for /l %z in (1,1,10^) do @echo %z^)') do @echo %a0

您会看到数字 10..100，现在只需添加管道，例如到sort 或more，随便：

for /f "delims=" %a in ('(for /l %z in (1,1,10^) do @echo %z^)^|sort') do @echo %a0

%a 和 0 之间将添加空格！ 看起来像通过管道回显某些内容会添加尾随空格，可以很容易地看到：

>_tempfile echo no space here
>_tempfile echo and here's a space|more

甚至

>_tempfile <nul set /p =also a space|sort

（可能使用echo打印提示）

当没有输出重定向（无论是文件还是命令）时，不会发生这种情况。 这是一个错误还是我错过了什么？我如何摆脱空间？ （除了用var:~0,-1 剥离最后一个字符的肮脏技巧）

Answer 1

优秀而有趣的问题（+1）

空间是由 CMD 解析器的管道机制引入的，而不是由 SORT 引入的。

当您使用 FOR /F 执行命令时，该命令将在其自己的 CMD shell 中执行。此外，管道的每一侧都在其自己的 CMD shell 中执行。请参阅Why does delayed expansion fail when inside a piped block of code? 了解更多信息。

因此，您的命令实际上实例化了 3 个 CMD shell，一个用于 FOR /F 命令，而后者又为管道的每一侧创建了 2 个。

您可以使用 %CMDCMDLINE% 动态变量查看命令是如何被解析并输入到 CMD shell 中的。因为我们是从命令行执行命令，所以我们需要对变量名中的至少一个字符进行两次转义，以便在到达最里面的 CMD shell 之前它不会被扩展。

这是带有结果的命令（前导 > 是我的命令提示符）：

>for /f "delims=" %a in ('(echo %^^^cmdcmdline%^&for /l %z in (1,1,10^) do @echo %z^)^|sort') do @echo %a0
1 0
10 0
2 0
3 0
4 0
5 0
6 0
7 0
8 0
9 0
C:\Windows\system32\cmd.exe  /S /D /c" ( echo %cmdcmdline% & FOR /L %z in (1 1 10) do @ echo %z )" 0

输出的最后一行是用于管道左侧的命令行。您可以看到解析器如何在许多地方添加空格。

您可以通过使用简单的批处理脚本来回显值而不是 ECHO 命令来规避该问题。

echoArgs.bat

@echo(%*

现在，当您运行此命令时，您会得到想要的结果

>for /f "delims=" %a in ('(for /l %z in (1,1,10^) do @echoArgs %z^)^|sort') do @echo %a0
10
100
20
30
40
50
60
70
80
90

另一种规避该问题的方法是使用 ECHO 命令创建一个变量并适当地转义该变量的扩展。

>set cmd=@(echo %z)

>for /f "delims=" %a in ('(for /l %z in (1,1,10^) do %^^^cmd%^)^|sort') do @echo %a0
10
100
20
30
40
50
60
70
80
90

---

编辑

>_tempfile echo and here's a space|more 的例子也很有趣。输出文件末尾有一个额外的空间。但是 Chad Nouis 是正确的，因为左侧的重定向，什么都没有被排序。任何命令都可以用在右边，结果都是一样的。

问题的根源仍然是解析器，但解析器重组命令的方式很有趣。

>>_tempfile echo %^cmdcmdline%|rem

>type _tempfile
C:\Windows\system32\cmd.exe  /S /D /c" echo %cmdcmdline% 1>_tempfile"

注意重定向是如何从命令的开头移动到结尾的，并且显式添加了1 的文件句柄。您当然可以看到多余的空间是从哪里来的。

Answer 2

重定向操作符适用于它们最接近的命令——而不是整行。

在您的三个测试用例中，您将echo 和set 命令的标准输出重定向到一个文件。通过重定向标准输出，没有任何东西可以通过管道传送到more 或sort。

在您的嵌套 for 循环示例中，我认为有一些不需要的括号会导致头痛。试试这个：

for /f "delims=" %a in ('for /l %z in (1,1,10^) do @echo %z^|sort') do @echo %a0