中断 10h 的功能 06h。滚动文本排列

Question

我需要使用中断 10h 的函数 06h 来实现滚动队列。问题是我有滚动线，但符号没有出现，光标消失了，什么也没有发生。也许我忘记了要考虑的事情？要编写代码，我使用FASM。该代码是引导加载程序的一部分。这是与滚动相关的一段代码：

cmp cx, 2001
je ScrollLine

我有一个计数器，当它达到 2001（从 1 开始计数）时，控制权传递给 ScrollLine。

滚动线：

mov ah, 06h
mov al, 1
mov bh, 07      
mov cx, 0000h
mov dx, 184Fh 
int 10h
ret

我完整的bootloader代码如下：

use16
org 7C00h

start:
    mov ah, 00h  
    mov al, 02h              
    int 10h

    mov ax, NewInt40
    call ChangeIVT

    mov cx, 0

wait_loop:
    xor ax, ax

    inc cx

    cmp cx, 2001
    je ScrollLine

    mov ah, 0
    int 16h

    push ax
    call PrintChar

    jmp wait_loop

NewInt40:   
    sti
    push ax
    mov ax, msg
    cmp bl, 3
    je PrintChar
    cmp bl, 2
    je PrintString
    cmp bl, 1
    je Clear
    cmp bl, 4
    je Scroll
    pop ax
    iret

ChangeIVT:

    push bx
    xor bx, bx

    mov es, bx
    mov bx, 40h
    shl bx, 2

    mov word [es:bx], ax
    mov word [es:bx+2], 0

    pop bx
    ret

PrintString:

    push si
    push bx
    push es
    mov si, ax

    mov ax, 0B800h
    mov es, ax

    xor bx, bx
    xor dx, dx

@@:
    lodsb   

    cmp al, 0
    je @f

    mov byte [es:bx], al
    mov byte [es:bx+1], 1Eh

    mov ah, 0Eh
    add bx, 2
    inc dx
    mov ah,02h
    mov al,02h  
    int 10h
    jmp @b

@@:
    pop es
    pop bx
    pop si
    ret

PrintChar:

    push bp
    mov bp, sp
    push bx
    push es
    push cx

    mov ax, 0B800h
    mov es, ax

    xor bx, bx
    xor dx, dx

    mov ah,3
    int 0x10

    movzx ax, dh
    movzx bx, dl
    mov cx, 80
    push dx
    mul cx
    pop dx
    add bx, ax  ; bx = 80 * dh + dl
    shl bx, 1   ; bx = 2 * (80 * dh + dl)



    mov ax, [bp + 4]
    mov byte [es:bx], al
    mov byte [es:bx+1], 1Eh

    cmp dl, 79
    jl @f

    inc dh
    mov dl, -1
@@:
    inc dl

    pop cx
    mov bh, 0

    mov ah, 2
    int 0x10

    pop es
    pop bx
    mov sp, bp
    pop bp
    ret

Clear:
   mov  AH,0      
   mov  AL,2      
   int  10H       
   ret

Scroll:
    mov ah, 06h
    mov al, 1
    mov bh, 07      
    mov cx, 0000h
    mov dx, 184Fh 
    int 10h
    ret

ScrollLine:
    mov bl, 4
    int 40h
    xor cx, cx
    ret

msg db "Hello, world!", 0Dh, 0Ah, 0

db 510-($-$$) dup (0)

db 55h, 0AAh

Answer 1

你用跳跃跟注。

在NewInt40 ISR 中，您有条件地跳转到子例程PrintString、PrintChar、Scroll 等，但从它们返回ret。

我不知道代码的结构是怎样的，所以我只介绍了使其工作所需的最小更改，没有什么可以称为良好实践时间>。

既然您正在编写引导加载程序，那么您现在肯定知道要修复什么了。

NewInt40:   
    sti
    push ax

    push bp             ;; Save caller's BP
    mov bp, sp          ;; Save SP, so we can restore the stack pointer

    push WORD _ni40_end ;; Push return address of every routine

    mov ax, msg
    cmp bl, 3
    je PrintChar
    cmp bl, 2
    je PrintString
    cmp bl, 1
    je Clear
    cmp bl, 4
    je Scroll


_ni40_end:          ;; NASM label
    mov sp, bp      ;; Restore stack pointer (in any case) 
    pop bp          ;; Restore caller BP

    pop ax
    iret

对不起，我是为 NASM 写的，不过翻译成 FASM 应该很容易。

附言
当您的引导加载程序“发疯”时，例如没有响应或自行操作，很可能是您“失去执行流程”的症状。
这意味着您正在执行不是您的代码的字节，当您返回不平衡的堆栈时会发生这种情况。
如果类似的事情再次发生，请仔细检查您的退货。