delphi 7，FastMM4 无法安装解决方法

Question

我正在开发一个使用来自sourceforge.net 的FastMM4 的应用程序。 所以我在开头就将FastMM4.pas 添加到了uses 子句中。在应用程序中，我需要像这样在finalization 的finalization 中的FinalizeMemoryManager; 之后运行batch 文件

  initialization
        RunInitializationCode;

  finalization
        {$ifndef PatchBCBTerminate}
        FinalizeMemoryManager;
        RunTheBatFileAtTheEnd; //my code here..calling a procedure
       {$endif}

 end.

那么我的 RunTheBatFileAtTheEnd 代码是：

 procedure RunTheBatFileAtTheEnd;
 begin
 //some code here....
  sFilePaTh:=SysUtils.ExtractFilePath(applicaTname)+sFileNameNoextension+'_log.nam';
 ShellExecute(applcatiOnHAndle,'open', pchar(sExeName),pchar(sFilePaTh), nil, SW_SHOWNORMAL) ;
 end;

为此，我需要在 fastmm4 单元的 uses 子句中使用 SysUtils,shellapi。 但使用它们 这条消息来了

但如果我从用途中删除SysUtils,shellapi，它就可以工作。 我仍然需要安装 fastmm4 的所有功能，但是 SysUtils,shellapi 没有安装 fastmm4

我有一个自己的单元，但它的最终化是在 fastmm4 最终化之前执行的。

谁能告诉我如何解决这个问题？

编辑- 1

unit FastMM4;
//...
...
implementation

 uses
   {$ifndef Linux}Windows,{$ifdef FullDebugMode}{$ifdef Delphi4or5}ShlObj,{$else}
  SHFolder,{$endif}{$endif}{$else}Libc,{$endif}FastMM4Messages,SysUtils,shellapi;

我的申请

 program memCheckTest;
   uses
      FastMM4,

EDIT-2：

（在@SertacAkyuz 回答之后），我删除了SysUtils 并且它有效，但我仍然需要运行批处理文件以通过RunTheBatFileAtTheEnd 打开外部应用程序。原因是..我希望外部应用程序仅在 FastMM4 退出 finalization 之后运行。 sExeName 是运行文件 sFilePaTh(.nam) 的应用程序。任何人都可以告诉如何做到这一点？没有uninstalling FastMM4。

Answer 1

FastMM 通过调用“system.pas”中的IsMemoryManagerSet 函数来检查是否设置了默认内存管理器，然后再安装它自己的。如果设置了默认内存管理器，它会拒绝设置自己的内存管理器并显示问题中显示的消息。

该消息中关于'fastmm4.pas' 的说明应该是项目.dpr 文件中的第一个单元，假设'fastmm4.pas' 本身没有被修改。

当您修改“fastmm4.pas”的uses 子句时，如果uses 子句中包含的任何单元具有initialization 部分，则该部分代码必须在“fastmm4.pas”的初始化部分之前运行。过'。如果该代码需要通过 RTL 分配/使用内存，则设置默认内存管理器。

因此，您必须注意将“fastmm4.pas”更改为不在 uses 子句中包含任何此类单元，例如“sysutils.pas”。

---

下面的示例代码（无错误检查、文件检查等）显示了如何在不分配任何内存的情况下使用记事本启动 FastMM 的日志文件（前提是日志文件存在）：

var
  CmdLine: array [0..300] of Char; // increase as needed
  Len: Integer;
  SInfo: TStartupInfo;
  PInfo: TProcessInformation;

initialization
  ...  // fastmm code

finalization
{$ifndef PatchBCBTerminate}
  FinalizeMemoryManager;       // belongs to fastmm

  // Our application is named 'Notepad' and the path is defined in AppPaths
  CmdLine := 'Notepad "';  // 9 Chars (note the opening quote)
  Len := windows.GetModuleFileName(0, PChar(@CmdLine[9]), 260) + 8;

  // assumes the executable has an extension.
  while CmdLine[Len] <> '.' do
    Dec(Len);

  CmdLine[Len] := #0;
  lstrcat(CmdLine, '_MemoryManager_EventLog.txt"'#0); // note the closing quote

  ZeroMemory(@SInfo, SizeOf(SInfo));
  SInfo.cb := SizeOf(SInfo);
  CreateProcess(nil, CmdLine, nil, nil, False,
                NORMAL_PRIORITY_CLASS, nil, nil, sInfo, pInfo);

{$endif}

end.

Answer 2

我同意 Sertac 的回答，但如果您坚持使用SysUtils.pas，也想给个建议。答案是不要使用它，并从中提取您需要的内容并将其放入您自己的副本中。下面是您需要的 - ExtractFilePath 使用了 LastDeliminator，它使用了 StrScan，还有 2 个常量，所以我将它们复制到这个新单元中并命名为 MySysUtils.pas。

这也被广泛用于那些不想编译一堆他们永远不会使用的额外代码的人（你必须绝对确定它不会在任何单元的任何地方使用）。

unit MySysUtils;

interface

const
  PathDelim = '\';
  DriveDelim = ':';

implementation

function StrScan(const Str: PWideChar; Chr: WideChar): PWideChar;
begin
  Result := Str;
  while Result^ <> #0 do begin
    if Result^ = Chr then
      Exit;
    Inc(Result);
  end;
  if Chr <> #0 then
    Result := nil;
end;

function LastDelimiter(const Delimiters, S: string): Integer;
var
  P: PChar;
begin
  Result := Length(S);
  P := PChar(Delimiters);
  while Result > 0 do begin
    if (S[Result] <> #0) and (StrScan(P, S[Result]) <> nil) then
      Exit;
    Dec(Result);
  end;
end;

function ExtractFilePath(const FileName: string): string;
var
  I: Integer;
begin
  I := LastDelimiter(PathDelim + DriveDelim, FileName);
  Result := Copy(FileName, 1, I);
end;

end.