如何在过程中将类引用（元类）作为参数传递？

Question

有两个对象：TFoo、TFoo2。

还有一个类引用：TFooClass = class of TFoo;

两者都是TPersistent的后代。

他们有自己的构造函数：

type
  TFoo = class(TPersistent)
  private
    FC:Char;
  public
    constructor Create; virtual;
  published
    property C:Char read FC write FC;
  end;
    
  TFoo2 = class(TFoo)
  public
    constructor Create; override;
  end;

  TFooClass = class of TFoo;

...

constructor TFoo.Create;
begin
  inherited Create;
  C :=' 1';
end;
    
constructor TFoo2.Create;
begin
  inherited Create;
  C := '2';
end;

我想从一个字符串创建一个TFoo2 对象，这实际上是它的类名：'TFoo2'

这是程序，它工作正常：

procedure Conjure(AClassName:string);
var
  PClass : TPersistentClass;
  p :TPersistent;
begin
  PClass := TPersistentClass(FindClass(AClassName))
  p := TFooClass(PClass).Create;  // <-- here is called appropriate constructor  
end;

现在，我想要类似的对象，例如：TBobodo、TBobodo2。

当然还有一个类参考：TBobodoClass = class of TBobodo;

等等……

现在，如何将类引用作为参数传递给过程，以确保调用正确的构造函数？

procedure Conjure(AClassName:string; ACLSREF: ???? ); // <-- something like that 
var
  PClass : TPersistentClass;
  p :TPersistent;
begin
  PClass := TPersistentClass(FindClass(AClassName))
  p := ACLSREF(PClass).Create;  // <-- something like that  
end;

有可能吗？

Answer 1

在 Delphi 7 中没有办法做你想做的事。元类引用必须在调用站点的编译时显式，而不是在运行时处理。

在 Delphi 2009 及更高版本中，您可能 ¹能够使用Generics 做某事，例如：

^{1：我自己还没试过。}

type
  TConjureHelper = class
  public
    class procedure Conjure<TClassType>(const AClassName: string);
  end;

class procedure TConjureHelper.Conjure<TClassType>(const AClassName: string);
var
  PClass : TPersistentClass;
  p : TPersistent;
begin
  PClass := TPersistentClass(FindClass(AClassName));
  p := TClassType(PClass).Create;
  ...
end;

...

TConjureHelper.Conjure<TFooClass>('TFoo2');
TConjureHelper.Conjure<TBobodoClass>('TBobodo2');
...

但 Delphi 7 肯定不支持泛型。

Answer 2

我遇到了同样的问题，经过一番挣扎，我找到了一个非常简单的解决方案：元类正是为此目的而发明的！ 在您的情况下，您可以将元类作为参数传递并直接使用它，而无需繁琐的查找类和类型转换。

type
  TFooClass = class of TFoo;

procedure Conjure(aFooClass : TFooClass); // <-- something like that 
var
  p :TPersistent;
begin
  p := aFooClass.Create;  // it will work!
end;

通过调用，您只需使用：

Conjure(TFoo); // <- for Foo class or
Conjure(TFoo2); // <- for Foo2 class and so on