调整 Excel 数据透视表以显示 OrderNumber 而不是计算？答案

【问题标题】：Tweaking a Excel Pivot Table to display a OrderNumber instead of a calculation?调整 Excel 数据透视表以显示 OrderNumber 而不是计算？
【发布时间】：2010-12-16 05:03:29
【问题描述】：

使用 Microsoft Excel 2007（或 2002）是否可以像这样创建数据透视数据？

具体来说，我想知道是否可以将“01(Y 0)”显示为非计算文本值，而不仅仅是 SUM/COUNT/MAX/等值。

【问题讨论】：

我不认为您可以使用数据透视表来做到这一点，但如果您对上面所示的平面表感到满意，您可以在 Excel 中使用 ADO 创建它。
@Remou - 你能指出任何可能对我有帮助的文档吗？

标签： excel-2007 pivot-table

【解决方案1】：

使用 ADO

Dim cn As Object
Dim rs As Object
Dim strFile As String
Dim strCon As String
Dim strSQL As String
Dim s As String
Dim i As Integer, j As Integer

''This is not the best way to refer to the workbook
''you want, but it is very convenient for notes
''It is probably best to use the name of the workbook.

strFile = ActiveWorkbook.FullName

''Note that if HDR=No, F1,F2 etc are used for column names,
''if HDR=Yes, the names in the first row of the range
''can be used.
''This is the Jet 4 connection string, you can get more
''here : http://www.connectionstrings.com/excel

strCon = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strFile _
    & ";Extended Properties=""Excel 8.0;HDR=Yes;IMEX=1"";"

''Late binding, so no reference is needed

Set cn = CreateObject("ADODB.Connection")
Set rs = CreateObject("ADODB.Recordset")


cn.Open strCon

strSQL = "TRANSFORM First(t.[Order Number]) AS OrdNo " _
    & "SELECT t.[Slot Number], t.Time " _
    & "FROM [Sheet2$] t " _
    & "GROUP BY t.[Slot Number], t.Time " _
    & "PIVOT t.Company"


rs.Open strSQL, cn, 3, 3


''Pick a suitable empty worksheet for the results

With Worksheets("Sheet3")
    For i = 1 To rs.Fields.Count
        .Cells(1, i) = rs.Fields(i - 1).Name
    Next

    .Cells(2, 1).CopyFromRecordset rs
End With

''Tidy up
rs.Close
Set rs = Nothing
cn.Close
Set cn = Nothing

【讨论】：