Groovy：自动扩展属性的所有设置器

Question

如果我有这样一个 groovy 类：

class WebSession{
    String firstName
    String lastName
    String email
}

我希望能够使用自动设置器来设置值。例如：

WebSessionuser = new WebSession()
webSession.firstName = 'John'

但是让它调用的 setter 做一些额外的事情，比如记录一些东西或将对象持久化到缓存。

如何在不必手动定义所有设置器的情况下做到这一点？到目前为止，我有这样的东西，但我不能让它工作：

    webSession.properties.each{ key, value ->
        if ( key != 'class' ) {
            String methodName = "set${key.capitalize()}";
            WebSession.metaClass[key]."${methodName}" = { -> delegate
                System.out.println("Setting key: ${key}");
                webSession[key] = delegate;
            }
        }

    }

另外，我不知道循环遍历属性名称减去“类”是否很麻烦，并且有更好的方法来获取声明的字段。

Answer 1

您可以通过实现void setProperty(String, Object) 和Object getProperty(String) 来拦截所有的getter 和setter。这是一个例子：

示例

def a = new WebSessionDecorator(new WebSession())

a.firstName = 'John'

println a.firstName

class WebSession {
    String firstName
    String lastName
    String email
}

class WebSessionDecorator {
    private WebSession delegate

    WebSessionDecorator(WebSession webSession) {
        this.delegate = webSession
    }

    void setProperty(String name, Object value) {
        println "LOG: Setting $name to $value"
        delegate.setProperty(name, value)        
    }

    def getProperty(String name) {
        println "LOG: Returning $name"
        delegate.getProperty(name)
    }
}

输出

输出如下：

LOG: Setting firstName to John
LOG: Returning firstName
John

说明

WebSessionDecorator 拦截所有财产访问，为您提供随心所欲的机会。然后，它将属性访问权委托给实际的WebSession。

我选择使用装饰器是为了避免重复调用getProperty() 和setProperty()，并且只有在适用时才可以使用装饰器。例如，您可能不想在单元测试中使用它。