无法使用 metaClass 覆盖脚本方法

Question

我试图通过对象的metaClass 重新定义方法来覆盖 Groovy 自定义 Script 类中定义的方法，但是更改被完全忽略，原始方法按原样调用。我在普通课程上尝试了同样的方法，它按预期工作，所以我想知道在自定义Script 的情况下有什么不同。这是我保存为 `/tmp/t.groovy 的 sn-p：

class Worker {
    def init() {
        throw new Exception('I always fail')
    }

    void start() {
        init()
        println('I never get to work')
    }
}

def worker = new Worker()
worker.metaClass.init = { println("dummy init") }
worker.start()

def shell = new GroovyShell()
def script = shell.parse('@groovy.transform.BaseScript TestScript _')
script.metaClass.init = { println("dummy init") }
script.start()

TestScript 类必须在其自己的文件中定义，GroovyShell 才能找到它，所以/tmp/TestScript.groovy 具有类：

abstract class TestScript extends Script {
    def init() {
        throw new Exception('I always fail')
    }

    void start() {
        init()
        println('I never get to work')
    }
}

这是我在 Mac OS 上使用 Groovy 2.4.14 运行时的输出：

$ groovy /tmp/t.groovy
dummy init
I never get to work
Caught: java.lang.Exception: I always fail
java.lang.Exception: I always fail
    at TestScript.init(TestScript.groovy:3)
    at TestScript.start(TestScript.groovy:7)
    at TestScript$start.call(Unknown Source)
    at t.run(t.groovy:19)

您可以看到对worker.metaClass 所做的更改是有效的，但对script.metaClass 所做的相同更改被忽略了。我尝试先在工作场景中跟踪调用，使用如下内容：

def worker = new Worker()
def m = new DelegatingMetaClass(worker.metaClass) {
        Object invokeMethod(Object object, String methodName, Object[] args) {
            println("invokeMethod ${methodName}(${args})")
            return super.invokeMethod(object, methodName, args)
        }

    }
m.initialize()
worker.metaClass = m
worker.start()

输出如下：

invokeMethod start([])
invokeMethod init([])
Caught: java.lang.Exception: I always fail
java.lang.Exception: I always fail
    ...

您可以看到start 和init 都被记录了。当我在脚本对象上尝试相同时：

def shell = new GroovyShell()
def script = shell.parse('@groovy.transform.BaseScript TestScript _')
def m = new DelegatingMetaClass(script.metaClass) {
        Object invokeMethod(Object object, String methodName, Object[] args) {
            println("invokeMethod ${methodName}(${args})")
            return super.invokeMethod(object, methodName, args)
        }

    }
m.initialize()
script.metaClass = m
script.start()

输出如下：

invokeMethod start([])
Caught: java.lang.Exception: I always fail
java.lang.Exception: I always fail
    ...

您可以看到对init 的调用永远不会被委托给invokeMethod。我在这里错过了什么？

Answer 1

TL;DR：实现 GroovyInterceptable 使脚本方法可通过元类覆盖。

我开始通过将def t = new Throwable(); t.fillInStackTrace(); t.printStackTrace() 添加到这两种方法来比较导致Worker.init 和TestScript.init 的标准化堆栈跟踪来寻找线索。看起来明显不同的部分是从start() 到init() 的堆栈，如下所示：

For Worker class:

    at Worker.init(t.groovy:3)
    at Worker$init$0.callCurrent(Unknown Source)
    at org.codehaus.groovy.runtime.callsite.CallSiteArray.defaultCallCurrent(CallSiteArray.java:51)
    at org.codehaus.groovy.runtime.callsite.AbstractCallSite.callCurrent(AbstractCallSite.java:157)
    at org.codehaus.groovy.runtime.callsite.AbstractCallSite.callCurrent(AbstractCallSite.java:161)
    at Worker.start(t.groovy:8)
    at Worker$start.call(Unknown Source)

For TestScript class:

    at TestScript.init(TestScript.groovy:3)
    at TestScript.start(TestScript.groovy:8)
    at TestScript$start.call(Unknown Source)

您可以看到从start 对init 的调用通过Worker 中的常规代码，而它直接在TestScript 中进行。

然后我注意到Script 扩展了GroovyObjectSupport，这意味着当Java 类的对象应该显示为Groovy 对象时扩展它的基类。当我在metaprogramming documentation 下搜索GroovyObjectSupport 时，我发现invokeMethod 只能与标记接口GroovyInterceptable 一起使用，并且在Script 类的类继承链中缺少它。一旦我让TestScript 实现GroovyInterceptable，覆盖就按预期工作了。

我还是要检查一下添加这个接口是否会让 Jenkins 管道 CPS 对我嗤之以鼻。