在代码引用中检索数组项

Question

作为爱好项目的一部分，我想动态创建一个函数，当提供浮点数组时，它可以使用数组元素执行一些算术并返回结果。

请注意，该函数必须在运行时创建。

我相信这可以通过使用 FSharp.Quotations.Expr 模块构造一个 lambda 表达式来完成。

举个简单的例子：

fun (arr: float array) -> 2.0 * arr.[0]

我可以使用以下代码引用重新创建它：

<@ fun (arr: float array) -> 2.0 * arr.[0] @>

将其打印到控制台会产生：

Lambda (arr,
        Call (None, op_Multiply,
              [Value (2.0), Call (None, GetArray, [arr, Value (0)])]))

我可以看到提到的GetArray 是位于FSharp.Core.LanguagePrimitives.IntrinsicFunctions.GetArray 的那个。

我的问题是... 如何在运行时创建Call (None, GetArray, [arr, Value (0)])？

---

到目前为止，我的（令人尴尬的）尝试是：

open System
open FSharp.Quotations

let arr = Var("arr", typeof<float array>, false)

let getArray = FSharp.Core.LanguagePrimitives.IntrinsicFunctions.GetArray.GetType().GetMethods().[0]

Expr.Lambda(arr, Expr.Call(getArray, [Expr.Var(arr); Expr.Value(0)]))

这会产生以下异常：

System.ArgumentException：“构建“args”时的类型不匹配：方法或索引器属性的参数无效。应为“System.Object[]”，但收到类型“System.Double[]”。

鉴于GetArray 看起来是一个通用函数，我不清楚为什么会这样。

我显然误解了这里相当基本的东西！

感谢您提供的任何建议。

Answer 1

现有的答案完美地解决了这个问题。我可以想到一个稍微的简化，那就是从最小的引用中提取GetArray 方法信息，这样您就不必担心使用反射手动找到方法。

open Microsoft.FSharp.Quotations

let arr = Var("arr", typeof<float array>, false)
let getArray<'T> = match <@ ([||] : 'T[]).[0] @> with Patterns.Call(_, mi, _) -> mi | _ -> failwith "Array access was not Call"
let expr = Expr.Lambda(arr, Expr.Call(getArray<float>, [Expr.Var(arr); Expr.Value(0)]))
printfn "%A" expr

如果方法被移动，这可能是一个更未来的证明，但它仍然只有在数组访问被公开为方法调用时才有效。

也许一种更有趣的方法是使用引号拼接，它可以让您将构建数组访问的位分隔到一个函数中，但将其写为引号：

let arr = Var("arr", typeof<float array>, false)

let getArray (e:Expr<'T[]>) (a:Expr<int>) = 
  <@ (%e).[%a] @>

let expr = 
  Expr.Lambda(arr, 
    getArray (Expr.Cast<float array>(Expr.Var(arr))) 
      (Expr.Cast<int>(Expr.Value(0))))

printfn "%A" expr

Answer 2

我认为这里的问题是您需要为GetArray 本身获取MethodInfo，这需要反射。我不确定是否有一种简单的方法可以做到这一点，但以下方法似乎可行：

let arr = Var("arr", typeof<float array>, false)
let getArray =
    let asm = System.Reflection.Assembly.Load("FSharp.Core")
    let typ = asm.DefinedTypes |> Seq.find (fun typ -> typ.Name = "IntrinsicFunctions")
    let getArrayGeneric = typ.GetMethod("GetArray")
    getArrayGeneric.MakeGenericMethod(typeof<double>)
let expr = Expr.Lambda(arr, Expr.Call(getArray, [Expr.Var(arr); Expr.Value(0)]))
printfn "%A" expr   // Lambda (arr, Call (None, GetArray, [arr, Value (0)]))

这会在FSharp.Core 程序集中找到通用的GetArray 方法，然后用double 对其进行实例化，以获得GetArray<double> 的MethodInfo，这正是您所需要的。