Nemerle 宏的中缀格式

Question

假设我需要一些非常特殊的乘法运算符。它可以在以下宏中实现：

macro @<<!(op1, op2)
{
    <[ ( $op1 * $op2 ) ]>
}

我可以像这样使用它

def val = 2 <<! 3

还有它的工作。

但我真正想要的是一些类似于“英语”的运算符，用于正在开发的 DSL：

macro @multiply(op1, op2)
{
    <[ ( $op1 * $op2 ) ]>
}

如果我尝试像这样使用它

def val = 2 multiply 3

编译器因 'expected ;' 而失败错误

有什么问题？如何实现这个中缀格式的宏？

Answer 1

直接来自编译器源代码：

namespace Nemerle.English
{
  [assembly: Nemerle.Internal.OperatorAttribute ("Nemerle.English", "and", false, 160, 161)]
  [assembly: Nemerle.Internal.OperatorAttribute ("Nemerle.English", "or", false, 150, 151)]
  [assembly: Nemerle.Internal.OperatorAttribute ("Nemerle.English", "not", true, 181, 180)]  

  macro @and (e1, e2) {
    <[ $e1 && $e2 ]>
  }

  macro @or (e1, e2) {
    <[ $e1 || $e2 ]>
  }

  macro @not (e) {
    <[ ! $e ]>
  }

你需要在周围撒上 OperatorAttributes，它就会起作用。顺便说一句，OperatorAttribute 定义如下：

public class OperatorAttribute : NemerleAttribute
{
  public mutable env : string;
  public mutable name : string;
  public mutable IsUnary : bool;
  public mutable left : int;
  public mutable right : int;
}

Answer 2

像往常一样，我比社区响应更快地找到答案 :) 因此，解决方案是简单地使用特殊的组装级别属性，将宏指定为二元运算符：

namespace TestMacroLib
{
  [assembly: Nemerle.Internal.OperatorAttribute ("TestMacroLib", "multiply", false, 160, 161)]
  public macro multiply(op1, op2)
  {
    <[ ( $op1 * $op2 ) ]>
  }
}