【发布时间】：2018-02-14 22:10:35
【问题描述】：
总结：
在下面的示例应用程序中，shared_ptr 在 Objective-C 块中被捕获。使用 Objective-C 运行时 API object_setIvarWithStrongDefault 将 Objective-C 块分配给动态创建的类的 ivar。当 Objective-C 对象被释放时，shared_ptr 正在泄漏，并且它保留的 C++ 对象没有被删除。这是为什么？
如果改用object_setIvar，则可以防止泄漏，但是一旦块超出范围，ivar 就会指向垃圾，因为object_setIvar 假定分配了unsafe_unretained。
我假设这与 Objective-C 如何捕获 C++ 对象、复制块以及 shared_ptr 如何处理被复制有关，但我希望有人能比下面列出的文档。
参考资料：
Apple's Blocks and Variables Documentation 包含有关 C++ 对象的简短部分，但我并不完全清楚它如何影响共享指针。
LLVM's Documentation on Blocks & C++ Support 比苹果的详细一点...
objc-class.mm 包含
object_setIvarWithStrongDefault的实现
背景故事：
此示例代码是从一个更大的项目中提取的，并且已显着减少到显示问题所需的最低限度。该项目是一个 Objective-C macOS 应用程序。该应用程序包含几个单一的 C++ 对象，它们是美化的键/值存储。每个对象都是同一类的一个实例，但以键类型为模板。我想动态创建一个包含由 C++ 类支持的类型化属性获取器的 Objective-C 类。
（是的，这一切都可以通过自己编写大量的 getter 来手动完成，但我不想这样做。C++ 类有足够的信息来了解属性的名称及其属性类型，因此我想使用一些元编程技术来“解决”这个问题。）
注意事项：
在理想情况下，我只能在适当的 shared_ptr 类型的 Objective-C 类上定义 iVar，但我不知道如何使用 Objective-C 运行时来做到这一点蜜蜂。
鉴于此：
std::shared_ptr<BackingStore<T>> backingStore
你如何使用它：
class_addIvar 和 object_setIvar
由于我无法弄清楚，我决定将 shared_ptr 包装到一个 Objective-C 块中，因为块是一流的对象，并且可以在需要 id 的地方传递。
示例应用程序：
（复制/粘贴到 CodeRunner 之类的内容中以查看输出）
#import <Foundation/Foundation.h>
#import <objc/runtime.h>
#import <memory>
typedef NSString* (^stringBlock)();
/**
* StoreBridge
*
* Objective-C class that exposes Objective-C properties
* which are "backed" by a C++ object (Store). The implementations
* for each property on this class are dynamically added.
*/
@interface StoreBridge : NSObject
@property(nonatomic, strong, readonly) NSString *storeName;
@end
@implementation StoreBridge
@dynamic storeName;
- (void)dealloc {
NSLog(@"StoreBridge DEALLOC");
}
@end
/**
* BackingStore
*
* C++ class that for this example just exposes a single,
* hard-coded getter function. In reality this class is
* much larger.
*/
class BackingStore {
public:
BackingStore() {
NSLog(@"BackingStore constructor.");
}
~BackingStore() {
NSLog(@"BackingStore destructor.");
}
NSString *name() const {
return @"Amazon";
}
// Given a shared_ptr to a BackingStore instance, this method
// will dynamically create a new Objective-C class. The new
// class will contain Objective-C properties that are backed
// by the given BackingStore.
//
// Much of this code is hard-coded for this example. In reality,
// a much larger number of properties are dynamically created
// with different return types and a new class pair is
// only created if necessary.
static id makeBridge(std::shared_ptr<BackingStore> storePtr) {
// For this example, just create a new class pair each time.
NSString *klassName = NSUUID.UUID.UUIDString;
Class klass = objc_allocateClassPair(StoreBridge.class, klassName.UTF8String, 0);
// For this example, use hard-coded values and a single iVar definition. The
// iVar will store an Objective-C block as an 'id'.
size_t ivarSize = sizeof(id);
NSString *ivarName = @"_storeNameIvar";
NSString *encoding = [NSString stringWithFormat:@"%s@", @encode(id)];
SEL selector = @selector(storeName);
// Implementation for @property.storeName on StoreBridge. This
// implementation will read the block stored in the instances
// iVar named "_storeNameIvar" and call it. Fixed casting to
// type 'stringBlock' is used for this example only.
IMP implementation = imp_implementationWithBlock((id) ^id(id _self) {
Ivar iv = class_getInstanceVariable([_self class], ivarName.UTF8String);
id obj = object_getIvar(_self, iv);
return ((stringBlock)obj)();
});
// Add iVar definition and property implementation to newly created class pair.
class_addIvar(klass, ivarName.UTF8String, ivarSize, rint(log2(ivarSize)), @encode(id));
class_addMethod(klass, selector, implementation, encoding.UTF8String);
objc_registerClassPair(klass);
// Create instance of the newly defined class.
id bridge = [[klass alloc] init];
// Capture storePtr in an Objective-C block. This is the block that
// will be stored in the instance's iVar. Each bridge instance has
// its own backingStore, therefore the storePtr must be set on the
// instance's iVar and not captured in the implementation above.
id block = ^NSString* { return storePtr->name(); };
Ivar iva = class_getInstanceVariable(klass, ivarName.UTF8String);
// Assign block to previously declared iVar. When the strongDefault
// method is used, the shared_ptr will leak and the BackingStore
// will never get deallocated. When object_setIvar() is used,
// the BackingStore will get deallocated but crashes at
// runtime as 'block' is not retained anywhere.
//
// The documentation for object_setIvar() says that if 'strong'
// or 'weak' is not used, then 'unretained' is used. It might
// "work" in this example, but in a larger program it crashes
// as 'block' goes out of scope.
#define USE_STRONG_SETTER 1
#if USE_STRONG_SETTER
object_setIvarWithStrongDefault(bridge, iva, block);
#else
object_setIvar(bridge, iva, block);
#endif
return bridge;
}
};
int main(int argc, char *argv[]) {
@autoreleasepool {
std::shared_ptr<BackingStore> storePtr = std::make_shared<BackingStore>();
StoreBridge *bridge = BackingStore::makeBridge(storePtr);
NSLog(@"bridge.storeName: %@", bridge.storeName);
// When USE_STRONG_SETTER is 1, output is:
//
// > BackingStore constructor.
// > bridge.storeName: Amazon
// > StoreBridge DEALLOC
// When USE_STRONG_SETTER is 0, output is:
//
// > BackingStore constructor.
// > bridge.storeName: Amazon
// > BackingStore destructor.
// > StoreBridge DEALLOC
}
}
【问题讨论】：
-
这里的问题是您的运行时生成的类没有释放 ivar 的析构函数！父
StoreBridge类中没有 ivar，因此它不知道在其上调用release。您需要有一个更智能的dealloc方法，它可以遍历这些 ivars 并释放它们（可能通过设置为nil，因为这听起来很安全）。
标签： c++ objective-c objective-c-blocks objective-c++ objective-c-runtime