SAS“找到比定义更多的位置参数”在宏中使用proc sql

Question

我遇到以下代码的错误“找到的位置参数比定义的多”：

%let my_list_of_vars = x, y, z;

%macro sumstats(my_vars);

proc sql;
    create table test2 as
    select distinct &my_vars.
    from my_dataset;
quit;

%mend sumstats;

%sumstats(&my_list_of_vars.);

我不太确定为什么 proc sql 不接受我的变量“x”、“y”和“z”列表，而是返回该错误。我在网上查看过，似乎无法找到解决此问题的方法。例如，这个网站 (http://support.sas.com/kb/31/012.html) 建议使用 %put 或 %bquote，但两者都不起作用。非常感谢一些指导。

谢谢。

Answer 1

您的代码解析为以下内容，因此您需要在宏调用中屏蔽逗号。

%sumstats(x, y, z);

错误：尝试使用%str()

%sumstats(%str(&my_list_of_vars.));

编辑： 您有示例 2，因此 %BQUOTE() 是正确的。

%sumstats(%BQUOTE(&my_list_of_vars.));

关于此问题和解决方案的 SAS 说明： http://support.sas.com/kb/31/012.html

Answer 2

不要尝试在变量名列表中使用逗号作为分隔符。这在普通 SAS 代码中不是很有用，并且在尝试在函数调用或宏调用中使用它们时会导致头痛和混乱。而是在需要时添加逗号。

%macro sumstats(my_vars);
* Normal SAS code ;
proc sort data=my_dataset(keep=&my_vars) out=test1 nodupkey;
run;

* Make version of list with commas for use in PROC SQL code ;
%local my_varsc ;
%let my_varsc = %sysfunc(compbl(&my_vars));
%let my_varsc = %sysfunc(translate(&my_varsc,',',' '));
proc sql;
  create table test2 as
    select distinct &my_varsc
    from my_dataset
  ;
quit;

%mend sumstats;

%let my_list_of_vars = x y z;
%sumstats(&my_list_of_vars.);