Racket：局部扩展递归定义

Question

我正在尝试编写一个行为类似于球拍定义的宏，但以某种方式处理完全扩展的球拍程序（为简单起见在下面的示例中进行了扩展）：

(define-syntax (define/expand stx)
  (syntax-case stx ()
    [(_ (head args ...) body body-rest ...)
       (let* ([define/racket (syntax/loc stx (define (head args ...) body body-rest ...))]
              [fully-expanded (local-expand define/racket 'top-level (list))])
           fully-expanded)]
    [(_ id expr) (syntax/loc stx (define id expr))]))

除非满足递归定义，否则一切正常：

(define/expand (sum n)
  (if (<= n 0)
      0
      (+ n (sum (- n 1)))))

运行它会引发错误

sum：模块中的未绑定标识符：sum

指向sum 的调用（不是定义）。显然sum 的定义没有被本地扩展器捕获。我尝试了一种直接的修复方法：创建新的本地定义上下文并将 head 绑定到其中：

(define-syntax (define/expand stx)
  (syntax-case stx ()
    [(_ (head args ...) body body-rest ...)
       (let* ([ctx (syntax-local-make-definition-context)]          ; <- These two lines added 
              [_ (syntax-local-bind-syntaxes (list #'head) #f ctx)] ; <--/
              [define/racket (syntax/loc stx (define (head args ...) body body-rest ...))]
              [fully-expanded (local-expand define/racket 'top-level (list) ctx)])
           fully-expanded)]
    [(_ id expr) (syntax/loc stx (define id expr))]))

它解决了问题（本地扩展成功将程序扩展为define-values），但创建了另一个：

模块：在：sum 中定义的上下文标识符

指向sum的定义。原因可能是扩展器将标识符绑定到 ctx 中的一个，而不是当前上下文中的 head。

直觉上这似乎不是一个罕见的问题，但我无法通过网络找到解决方案。我认为我应该以某种方式使用local-expand/capture-lifts 和syntax-local-lift-expression，但我不知道如何正确使用它。有人可以澄清发生了什么和/或提示如何解决它吗？

Answer 1

让我们在顶层 (repl) 中尝试您的第一个程序：

#lang racket
(define-syntax (define/expand stx)
  (syntax-case stx ()
    [(_ (head args ...) body body-rest ...)
     (let*
         ([define/racket  (syntax/loc stx (define (head args ...) body body-rest ...))]
          [fully-expanded (local-expand define/racket 'top-level (list))])
       fully-expanded)]
    [(_ id expr)
     (syntax/loc stx (define id expr))]))

然后在repl中：

Welcome to DrRacket, version 6.6.0.3--2016-07-28(-/f) [3m].
Language: racket, with debugging [custom]; memory limit: 1024 MB.
> (define/expand (sum n)
  (if (<= n 0)
      0
      (+ n (sum (- n 1)))))
.#<syntax:3:2 (define-values (sum) (lambda ...>
> (sum 5)
15

这表明您的程序在顶层运行。

相同方法在模块上下文中不起作用的原因 是#%module-begin 使用了形式的部分扩展 在扩展表达式之前检测定义。 换句话说，定义/扩展必须告诉#%module-begin 它扩展为sum 的定义，但必须延迟使用 local-expand 直到 #%module-begin 检测到所有 在模块级别绑定标识符。

这建议采用两步方法：

#lang racket

(define-syntax (delay-expansion stx)
  (syntax-case stx ()
    [(_delay-expansion more ...)
     (let ([fully-expanded (local-expand #'(lambda () more ...) 'module (list))])
       (display fully-expanded)
       fully-expanded)]))

(define-syntax (define/expand stx)
  (syntax-case stx ()
    [(_ (head args ...) body body-rest ...)
     (syntax/loc stx
       (define (head args ...)
         ((delay-expansion
           body body-rest ...))))]
    [(_ id expr)
     (syntax/loc stx
       (define id expr))]))


(define/expand (sum n)
  (if (<= n 0)
      0
      (+ n (sum (- n 1)))))

(sum 5)

在此处查看更多信息：https://groups.google.com/d/msg/racket-users/RB3inP62SVA/54r6pJL0wMYJ